Array of Strings

[rupert (Gast)]

Hallo,

für eine Testbench wollte ich gerne ein array von strings haben, die mir 
mode infos für das Terminal ausgeben, aber unterschiedlichen Längen 
haben.
Ein einfaches array erstellen geht wohl nicht, durch die 
unterschiedlichen Stringlängen. Was ich bis jetzt gefunden habe ist 
folgendes:

type line_vector is array(0 to 2) of line;
variable modes : line_vector := (
  new string'("mode on"),
  new string'("mode test"),
  new string'("mode off")
);

Wenn ich mir jetzt aber einen mode ausgeben lasse möchte in Modelsim 
Terminal
mit z.B.

report modes(0) severity note;

Bekomme ich die Fehlermeldung:
"Target type std.STANDARD.STRING in variable assignment is different 
from expression type std.TEXTIO.LINE."

Ich würde aber einen String erwarten.

Hat jemand mit sowas schon Erfahrung, bzw. gibt es eine 
(einfache)Konvertierung von Line nach String ?

[Markus F. (mfro)]

der Typ "line" ist zunächst mal nix anderes als ein Zeiger (access) auf 
String. Du kannst den entsprechend verwenden oder den Stringzeiger 
gleich selber bauen:

--  Hello world program.
use std.textio.all; -- Imports the standard textio package.

--  Defines a design entity, without any ports.
entity hello is
end hello;

architecture behaviour of hello is
    type str_acc is access string;
    type str_acc_arr is array (1 to 10) of str_acc;

    constant CHARS : string := "ABCDEFGHIJK";
begin
    process
        variable l : str_acc_arr;
    begin
        for i in 1 to 10 loop
            l(i) := new string(1 to i);
            for j in 1 to i loop
                l(i)(j) := CHARS(j);
            end loop;
        end loop;

        for i in 1 to 10 loop
            report "i=" & integer'image(i) & ", l(i)=" & l(i).all severity note;
        end loop;
        wait;
   end process;
end behaviour;

[rupert (Gast)]

Vielen Dank. Das hilft mir sehr weiter und macht das ganze 
verständlicher.

Gibt es für den Zeiger, access Typ irgendwo eine Auflistung welche 
Attribute man verwenden kann ? wie z.B. das ".all"

[Markus F. (mfro)]

rupert schrieb:
> Vielen Dank. Das hilft mir sehr weiter und macht das ganze
> verständlicher.
>
> Gibt es für den Zeiger, access Typ irgendwo eine Auflistung welche
> Attribute man verwenden kann ? wie z.B. das ".all"

.all ist kein Attribut, sondern einfach das "Dereferezierungs-Suffix".

Sehr viel mehr gibt es über access Typen auch gar nicht zu wissen 
(deallocate fehlt noch und die Tatsache, dass es für Array- und 
Record-Member eine verkürzte Schreibweise gibt, bei der man auf das .all 
verzichten kann).

Ansonsten hat es - soweit bekannt - noch niemandem geschadet, ein gutes 
Buch zu lesen ;). Ashenden's "Designer's Guide to VHDL" ist definitiv 
ein solches (auch wenn access-Typen dort nur ein paar Seiten der 
Schwarte ausmachen).

[Ingo L. (corrtexx)]

rupert schrieb:
> variable modes : line_vector := (
mach mal

variable modes : line_vector := )

SCNR