Taster Abrage mit gedrückt halten

[Hunter (Gast)]

Hallo,
ich wollte einen Zähler programmieren,
der bei gedrückt gehaltenem Taster weiterhochzählt,
jedoch funktioniert das Gedrückthalten nicht richtig.
Den Code habe ich im Laufe des AVR ASM Taster Tutorial
geschrieben.

Vielleicht findet ihr ja meinen Denkfehler:

.def  iwr0        = R1
.def  iwr1        = R2

.def  key_state      = R4
.def  key_press      = R5
.def  key_rep_press    = R6
.def  key_rep        = R16

.def  temp1        = R17
.def  temp2        = R18
.def  temp3        = R19
.def  counter        = R20

.equ  KEY_PORT      = PORTB
.equ  KEY_DDR        = DDRB
.equ  KEY_PIN        = PINB
.equ  LED          = 1
.equ  BTN1        = 0
.equ  BTN2        = 1
.equ  KEY_REPEAT_START  = 40
.equ  KEY_REPEAT_NEXT    = 15

.equ  PRESCL_1024      = 1<<CS00 | 1<<CS02

.equ  XTAL        = 8000000

.org 0x0000
    rjmp  init

.org OVF0addr
    rjmp  timer_overflow0

timer_overflow0:
    push  R0
    in    R0, SREG
    push  R0

    push  R16
    ldi    R16, -( XTAL / 1024 * 10 / 1000 + 1 )
    out    TCNT0, R16
    pop    R16

get8key:
    in    R0, KEY_PIN
    com    R0
    eor    R0, key_state
    and    iwr0, R0
    com    iwr0
    and    iwr1, R0
    eor    iwr1, iwr0
    and    R0, iwr0
    and    R0, iwr1
    eor    key_state, R0
    and    R0, key_state
    or    key_press, R0
    tst    key_state
    breq  get8key_rep
    dec    key_rep
    brne  get8key_finish
    mov    key_rep_press, key_state
    ldi    key_rep, KEY_REPEAT_NEXT
    rjmp  get8key_finish

get8key_rep:
    ldi    key_rep, KEY_REPEAT_START

get8key_finish:
    pop    R0
    out    SREG, R0
    pop    R0
    reti
  
.include "lcd-routines.asm"

init:
    ldi    temp1, LOW(RAMEND)
    out    SPL, temp1
    ldi    temp1, HIGH(RAMEND)
    out    SPH, temp1

    ldi    temp1, 1<<BTN1 | 1<<BTN2
    out    KEY_PORT, temp1

    ldi    temp1, PRESCL_1024
    out    TCCR0B, temp1
    ldi    temp1, 1<<TOIE0
    sts    TIMSK0, temp1

    rcall  lcd_init
    rcall  lcd_clear

    clr    key_state
    clr    key_press
    clr    key_rep_press
    clr    key_rep

main:
    ldi    counter, 0
    rjmp  update_lcd

loop:  
    ; normaler Tastendruck
    cli
    mov    temp1, key_press
    clr    key_press
    sei
    cpi    temp1, BTN1+1
    breq  increment
    cpi    temp1, BTN2+1
    breq  decrement

    ; Tastendruck gedrückthalten
    cli    
    mov    temp1, key_rep_press
    clr    key_rep_press
    sei
    cpi    temp1, BTN1+1
    breq  increment
    cpi    temp1, BTN2+1
    breq  decrement

    rjmp  loop

increment:
    inc    counter
    rjmp  update_lcd

decrement:
    dec    counter

update_lcd:
    mov    temp1, counter
    rcall  lcd_clear
    rcall  lcd_number
    rjmp  loop

; Left Scroll Display
lcd_lscroll:
    push  temp1
    ldi    temp1, 0b00011000
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret

; Right Scroll Display
lcd_rscroll:
    push  temp1
    ldi    temp1, 0b00011100
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret
; Move Cursor Left
lcd_lmove_cursor:
    push  temp1
    ldi    temp1, 0b00010000
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret
; Move Cursor Right
lcd_rmove_cursor:
    push  temp1
    ldi    temp1, 0b00010100
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret

text:  .db    "Start Counter", 0

[Klaus R. (klara)]

Gibt es denn keinen Debugger?
mfg Klaus

[Hunter (Gast)]

Nein, leider habe ich keinen Debugger parat.

[Stefan F. (Gast)]

Das gute(?) alte AVR Studio 4.19 enthält sowohl einen Simulator als auch 
einen Debugger, der für diese Aufgabe sicher gut geeignet ist.

[Hunter (Gast)]

Ich habe jetzt mit Atmel Studio 7 mein Programm gedebuggt,
aber da hat alles so funktioniert wie es soll.
An der Hardware kann es aber eigentlich auch nicht liegen,
weil der normale Tastendruck auch funktioniert,
nur der gehaltene Tastendruck funktioniert nicht.

[expliziter Klammersetzer (Gast)]

Hunter schrieb:
> ldi    R16, -( XTAL / 1024 * 10 / 1000 + 1 )

Setze mal explizit Klammern um die Rechenoperationen. Dann versteht der 
Assembler, wie du den Timer oldschool vorladen möchtest.

[Hunter (Gast)]

In etwa so?

ldi    R16, -( (((XTAL / 1024) * 10) / 1000) + 1 )

Leider erkennt das Programm immer noch nicht den langen Tastendruck.

[M.K. B. (mkbit)]

Ich habe mal drübergeschaut ohne das Programm genau zu verstehen. 
Außerdem habe ich schon lange keinen Assembler mehr programmiert.

Könnte es sein, dass get8key_rep immer aufgerufen wird und damit der 
Zähler nie ablaufen kann.

[Hunter (Gast)]

Der get8key_rep Abschnitt wird doch nur aufgerufen,
wenn die Zero-Flag durch tst gesetzt wurde im
Status Register, also wenn keine Taste gedrückt wird.

Ich denke das geht schon so, da auch der Debugger im Simulator
aus der Schleife ausbrechen konnte.

[Mario M. (thelonging)]

In key_state sind nicht genutzte Pins ständig auf 1 gesetzt. Dadurch ist 
Repeat ständig aktiv und Du bekommst in key_rep_press nie die erwarteten 
Werte. Also musst Du vor "tst key_state" alle nicht genutzten Bits 
maskieren und darfst später auch nur die genutzten Bits in key_rep_press 
übernehmen.

[Hunter (Gast)]

Aber die Pins an dem der Taster nicht gedrückt wird sind doch im Zustand 
1
und diese werden doch dann durch den Befehl com zu 0?

[S. Landolt (Gast)]

Um welchen Controller geht es eigentlich?

[Mario M. (thelonging)]

Die nicht genutzten Pins sind Ausgänge, stehen auf 0 und werden damit zu 
Einsen. Wenn Du die Pins nicht anderweitig brauchst, kannst Du als bösen 
Hack den KEY_PORT mit 0xff initialisieren.

[Hunter (Gast)]

Ich verwende den Atmega328.

[Hunter (Gast)]

Mario M. schrieb:
> Die nicht genutzten Pins sind Ausgänge, stehen auf 0 und werden damit zu
> Einsen.

Aber sind die nicht genutzten Pins nicht auf Eingang geschalten?

[Mario M. (thelonging)]

Stimmt, hab Quatsch geschrieben. Die Pins sind Eingänge, es fehlt aber 
der Pullup. Egal wie, maskiere key_state entsprechend in der 
Interruptroutine, dann funktioniert es.

[Hunter (Gast)]

Aber was soll ich denn da maskieren, wenn die gedrückten Tasten 1 und
die nicht gedrückten 0 sind?

[S. Landolt (Gast)]

Wie Mario M. um 15:41 schrieb!

Wenn es nicht anders verstanden wird, hier im Detail für Taster auf B0 
(ziemlich wüst allerdings):

...
    or    key_press, R0
 ldi r24,$01
 and key_press,r24
    tst    key_state
.
.
.
    mov    key_rep_press, key_state
 ldi r24,$01
 and key_rep_press,r24
    ldi    key_rep, KEY_REPEAT_NEXT
...

Und die Zeiten sind etwas knapp bemessen.

[Mario M. (thelonging)]

Als erste Abhilfe initialisiere mal KEY_PORT mit 0ffh. Wahrscheinlich 
funktioniert es dann schon.

[S. Landolt (Gast)]

So ist es.
Läuft sogar besser, das Zeitenproblem ist weg.

[Hunter (Gast)]

Ja, so funktioniert das gut,
aber dann kann ich den Port nicht
für andere Sachen benutzen.

Kann es vielleicht sein, dass auch
Probleme an dem Port auftauchen, weil
der Programmer und der Quartz an den PortB
angeschlossen ist?

[Mario M. (thelonging)]

Guck Dir mal die C-Variante von Peter Danneggers Tastenentprellung an. 
Da sieht man, wie es richtig gemacht wird. Stichwort REPEAT_MASK.

https://www.mikrocontroller.net/articles/Entprellung#Timer-Verfahren_.28nach_Peter_Dannegger.29

[Hunter (Gast)]

Ich habe meinen Code jetzt mal ein wenig angepasst
an die C-Routine von Peter Dannegger.
Jetzt funktioniert eigentlich alles soweit,
jedoch kommt es ab und zu vor bei normalen Tastendrücken,
dass der nicht erkannt wird.

Hier nochmal mein aktualisierter Code:

.def  iwr0        = R1
.def  iwr1        = R2

.def  key_state      = R4
.def  key_press      = R5
.def  key_rep_press    = R6
.def  key_rep        = R16

.def  temp1        = R17
.def  temp2        = R18
.def  temp3        = R19
.def  counter        = R20

.equ  KEY_PORT      = PORTB
.equ  KEY_DDR        = DDRB
.equ  KEY_PIN        = PINB
.equ  LED          = 1
.equ  KEY0        = 0
.equ  KEY1        = 1
.equ  ALL_KEYS      = (1<<KEY0 | 1<<KEY1)

.equ  KEY_REPEAT_MASK    = (1<<KEY0 | 1<<KEY1)
.equ  KEY_REPEAT_START  = 50
.equ  KEY_REPEAT_NEXT    = 20

.equ  PRESCL_1024      = (1<<CS00 | 1<<CS02)

.equ  XTAL        = 8000000

.org 0x0000
    rjmp  init

.org OVF0addr
    rjmp  timer_overflow0

timer_overflow0:
    push  temp1
    push  R0
    in    R0, SREG
    push  R0

    push  R16
    ldi    R16, -( XTAL / 1024 * 10 / 1000 + 1 )
    out    TCNT0, R16
    pop    R16

get8key:
    in    R0, KEY_PIN
    com    R0
    eor    R0, key_state    ; key changed?
    and    iwr0, R0      ; count in iwr0 and iwr1
    com    iwr0
    and    iwr1, R0
    eor    iwr1, iwr0
    and    R0, iwr0
    and    R0, iwr1
    eor    key_state, R0    ;
    and    R0, key_state
    or    key_press, R0
    ldi    temp1, KEY_REPEAT_MASK
    and    key_state, temp1
    tst    key_state
    breq  get8key_rep
    dec    key_rep
    brne  get8key_finish
    mov    key_rep_press, key_state
    ldi    key_rep, KEY_REPEAT_NEXT
    rjmp  get8key_finish

get8key_rep:
    ldi    key_rep, KEY_REPEAT_START

get8key_finish:
    pop    R0
    out    SREG, R0
    pop    R0
    pop    temp1
    reti
  
.include "lcd-routines.asm"

init:
    ldi    temp1, LOW(RAMEND)
    out    SPL, temp1
    ldi    temp1, HIGH(RAMEND)
    out    SPH, temp1

    ldi    temp1, ALL_KEYS
    com    temp1
    out    KEY_DDR, temp1

    ldi    temp1, ALL_KEYS
    out    KEY_PORT, temp1

    ldi    temp1, PRESCL_1024
    out    TCCR0B, temp1
    ldi    temp1, 1<<TOIE0
    sts    TIMSK0, temp1

    rcall  lcd_init
    rcall  lcd_clear

    clr    key_state
    clr    key_press
    clr    key_rep_press
    clr    key_rep

main:
    ldi    counter, 0
    rjmp  update_lcd

loop:  
    rcall  get_short_key
    cpi    temp1, 1<<KEY0
    breq  increment
    cpi    temp1, 1<<KEY1
    breq  decrement

    rcall  get_long_key
    cpi    temp1, 1<<KEY0
    breq  increment
    cpi    temp1, 1<<KEY1
    breq  decrement

    rjmp  loop

increment:
    inc    counter
    rjmp  update_lcd

decrement:
    dec    counter

update_lcd:
    mov    temp1, counter
    rcall  lcd_clear
    rcall  lcd_number
    rjmp  loop

; normaler Tastendruck
get_short_key:
    cli
    mov    temp1, key_press
    clr    key_press
    sei
    ret

; Tastendruck gedrückthalten
get_long_key:
    cli    
    mov    temp1, key_rep_press
    clr    key_rep_press
    sei
    ret

; Left Scroll Display
lcd_lscroll:
    push  temp1
    ldi    temp1, 0b00011000
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret

; Right Scroll Display
lcd_rscroll:
    push  temp1
    ldi    temp1, 0b00011100
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret
; Move Cursor Left
lcd_lmove_cursor:
    push  temp1
    ldi    temp1, 0b00010000
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret
; Move Cursor Right
lcd_rmove_cursor:
    push  temp1
    ldi    temp1, 0b00010100
    rcall  lcd_command
    rcall  delay5ms
    pop    temp1
    ret

text:  .db    "Start Counter", 0

[Mario M. (thelonging)]

In Peters Routine wird im Interrupt key_state nicht geändert und es 
werden auch nur die repetierenden Bits zurück gegeben:

    mov    temp1, key_state
    andi   KEY_REPEAT_MASK
    breq   get8key_rep
    dec    key_rep
    brne   get8key_finish
    mov    key_rep_press, temp1
    ldi    key_rep, KEY_REPEAT_NEXT
    rjmp   get8key_finish

[Mario M. (Gast)]

Korrektur:

 ANDI temp1, KEY_REPEAT_MASK

[Hunter (Gast)]

Ich bedanke mich bei euch für eure große Hilfe.
Das Problem scheint nun gelöst zu sein.