NTP Uhr geht 2 stunden zurück

[nilo (Gast)]

Hi,

Kann mir jemand sagen warum bei diesem Beispielcode die Uhr 2 Stunden 
zurück geht?

 #include <NTPClient.h>
// change next line to use with another board/shield
#include <ESP8266WiFi.h>
//#include <WiFi.h> // for WiFi shield
//#include <WiFi101.h> // for WiFi 101 shield or MKR1000
#include <WiFiUdp.h>

const char *ssid     = "FRITZ!Box 7490";
const char *password = "oYYo8885";

WiFiUDP ntpUDP;

// By default 'pool.ntp.org' is used with 60 seconds update interval and
// no offset
NTPClient timeClient(ntpUDP);

// You can specify the time server pool and the offset, (in seconds)
// additionaly you can specify the update interval (in milliseconds).
// NTPClient timeClient(ntpUDP, "europe.pool.ntp.org", 3600, 60000);

void setup(){
  Serial.begin(115200);
  WiFi.begin(ssid, password);

  while ( WiFi.status() != WL_CONNECTED ) {
    delay ( 500 );
    Serial.print ( "." );
  }

  timeClient.begin();
}

void loop() {
  timeClient.update();

  Serial.println(timeClient.getFormattedTime());

  delay(1000);
}

[Hannes J. (Firma: _⌨_) (pnuebergang)]

Lokale Zeitzone + Sommerzeit = 2 Stunden vor GMT.

[Μαtthias W. (matthias)]

NTP liefert UTC

[leo (Gast)]

nilo schrieb:
> Kann mir jemand sagen warum bei diesem Beispielcode die Uhr 2 Stunden
> zurück geht?

Google mal: ntpclient arduino timezone

Wir haben grad MESZ (+2 UTC)

leo

[nilo (Gast)]

Hi,

Okay entweder bin ich zu blöd dafür das zu suchen oder es gibt 
nichts(wohl eher ersteres)

[Theor (Gast)]

nilo schrieb:
> Hi,
>
> Okay entweder bin ich zu blöd dafür das zu suchen oder es gibt
> nichts(wohl eher ersteres)

Nein. Die Antworten sind weder so noch so zu verstehen.

Mit der Bemerkung über "UTC" bzw. "MESZ (UTC +2) will man Dir vielmehr 
zu verstehen geben, dass es sich hier nicht um einen Fehler im Programm 
handelt.
Vielmehr hast Du einfach nur nicht berücksichtig, dass ein NTP-Server 
die UTC-Zeit liefert und nicht die lokale Zeit. Du brauchst also nur 
zwischen (wann war das? Mai?) und Oktober 2 Stunden zu addieren und 
ansonsten 1 Stunde um auf die lokale Zeit in Deutschland (und einigen 
anderen Ländern) zu kommen.

Voilà und der Frosch ist gegessen. :-)

Falls Du etwas mehr darüber wissen willst, lies einfach was über 
Zeitzonen und Sommer- bzw. Winterzeit.

[Joachim B. (jar)]

Theor schrieb:
> Du brauchst also nur
> zwischen (wann war das? Mai?) und Oktober 2 Stunden zu addieren

ist aber gefährlich zur Umstellung MEZ (Zeitzone +1)

pünktlich um 3 Uhr wird auf 2 Uhr umgestellt, es wird wieder 3 und wer 
da wieder umstellt ....... :)

[nilo (Gast)]

Aber dann passt die zeit doch bei der Nächsten Umstellung wieder nicht 
oder ?

wollten die diesen blödsinn nicht abschaffen ?

[Axel S. (a-za-z0-9)]

nilo schrieb:
> Aber dann passt die zeit doch bei der Nächsten Umstellung wieder nicht
> oder ?

Oder

Die Zeit paßt immer. Es ist halt UTC. Daß du Sonderlocken willst, 
interessiert den NTP Client nicht die Bohne. Und wenn du unfähig bist, 
deine lokale Zeitzone herauszubekommen und von UTC dahin umzurechnen, 
dann ist das ganz allein dein Problem.

[frequent guest (Gast)]

Schau Dir https://github.com/JChristensen/Timezone an, das sollte 
helfen.

[Michael U. (amiga)]

Hallo,

das ESP8266 SDK bringt die komplette Posix-Timelib mit, auch in der 
ArduinoIDE.

#include <ESP8266WiFi.h>
#include <time.h>

#define WIFI_SSID "xxxxxxxxxx"
#define WIFI_PASSWORD "xxxxxxxxxx"

//######################################################################

void setup()
{
  Serial.begin(115200);
  Serial.println("\r\nReset");

// Start WiFi
  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

  Serial.print("Wifi connect.");
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("OK");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());

// Start Time service.
  configTime(0, 0, "pool.ntp.org", "time.nist.gov");
  setenv("TZ", "CET-1CEST,M3.5.0,M10.5.0/3", 0);          // Zeitzone MEZ setzen

  Serial.println("\nWaiting for time");

  while (!time(nullptr)) // vorsichtshalber auf die Initialisierund der Lib warten
  {
    Serial.print(".");
    delay(500);
  }
  Serial.println("OK");
  delay (1000); // Es kann einen Moment dauern, bis man die erste NTP-Zeit hat, solange bekommt man noch eine ungültige Zeit
  
  time_t now = time(nullptr);
  Serial.println(ctime(&now));
}

//----------------------------------------------------------------------

void loop()
{ 
  static byte old_sekunde = 99; 
  
  time_t now = time(nullptr);
  struct tm * timeinfo;
  timeinfo = localtime(&now);

  if (old_sekunde != timeinfo->tm_sec)
  {    
    Serial.printf("%02d:%02d:%02d",timeinfo->tm_hour,timeinfo->tm_min,timeinfo->tm_sec);
    Serial.println();  
    old_sekunde = timeinfo->tm_sec;
  }
}

Die Ausgabe in der loop() ist nur als Besipiel, näheres zur posix-timlib 
findet man in Netz.

Gruß aus Berlin
Michael

[Urlauber (Gast)]

nilo schrieb:
> Kann mir jemand sagen warum bei diesem Beispielcode die Uhr 2 Stunden
> zurück geht?

Komisch, hier auf Island liefert das Programm die richtige Zeit.

[Manfred (Gast)]

Urlauber schrieb:
> Komisch, hier auf Island liefert das Programm die richtige Zeit.

Kasper, sehr hilfreich - die Zeitzone von Island ist UTC / GMT, 
Sommerzeit gibt es dort nicht.

nilo schrieb:
> warum bei diesem Beispielcode die Uhr 2 Stunden zurück geht?

Befasse Dich aus folgendem Beispiel:
Michael U. schrieb:

setenv("TZ", "CET-1CEST,M3.5.0,M10.5.0/3", 0);  // Zeitzone MEZ setzen

mit der variable "setenv" und suche nach, wie die vergleichbare Funktion 
in Deinem Beispiel heisst, dazu gibt es sogar einen Kommentar in Deinem 
Quelltext.

Kopieren und Verstehen, zwei Gegensätze treffen aufeinander :-(

[Thomas E. (thomase)]

Manfred schrieb:
> Kasper, sehr hilfreich - die Zeitzone von Island ist UTC / GMT,
> Sommerzeit gibt es dort nicht.

Boahh. Und ich dachte, das hätte was mit dem Eyjafjallajökull zu tun.

[Axel S. (a-za-z0-9)]

Manfred schrieb:
> Urlauber schrieb:
>> Komisch, hier auf Island liefert das Programm die richtige Zeit.
>
> Kasper, sehr hilfreich - die Zeitzone von Island ist UTC / GMT,
> Sommerzeit gibt es dort nicht.

Cool. Endlich hat einer den Witz erklärt.
Dann kann ich jetzt beruhigt ins Bett gehen.

[Info (Gast)]

Michael U. schrieb:
> das ESP8266 SDK bringt die komplette Posix-Timelib mit, auch in der
> ArduinoIDE.

Super, danke!
Damit sind endlich die ganzen unvollständigen "NTP"-Implementierungen 
hinfällig (ohne Laufzeitkorrektur). Leider weiß davon fast niemand. Und 
selbst, als ich danach gesucht habe, fand ich nur wenig Infos dazu.

[Info (Gast)]

https://github.com/esp8266/Arduino/blob/master/libraries/esp8266/examples/NTP-TZ-DST/NTP-TZ-DST.ino

https://github.com/esp8266/Arduino/blob/master/cores/esp8266/time.cpp