ESP Frage zu Setup-Code, mit reconnect, etc.

[Klausi (Gast)]

Hallo allerseits,
in meinen jetzigen Projekten arbeite ich viel mit Esp8266, die über WiFi 
und MQTT mit einem Raspi kommunizieren. Soweit alles gut.

Über die letzten Monate habe ich das Setup, bzw. das Verhalten bei 
verlorenen Verbindungen (z.B. Wlan für x Minuten tot, oder Verbindung 
schlecht oder was es auch gibt) immer wieder erweitert.

Es würde mich freuen wenn ihr über diesen Code einmal drüberschauen 
könntet.
Ich bin sehr offen für Kritik und Verbesserungsvorschläge (ich habe das 
Programmieren nie richtig erlernen dürfen, deswegen gibt es bestimmt 
Fehler/ineffektive Zeilen ;)

An sich funktioniert dieser Code, aber ich würde sehr gerne einmal eure 
Meinung hören. Vielleicht hat ja jemand ähnliche Zeilen bei sich, und 
kann diese gerne als Alternative vorschlagen.

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
const char* ssid = "SSID";
const char* password = "PASSWORD";
const char* mqtt_server = "192.168.178.31";
const char* deviceID = "WEMOSD1mini";

WiFiClient wifiClient;                  //create an instance of the WiFi client
PubSubClient MQTTclient(wifiClient);    //create an instance of the MQTT client, based on the WiFi client

long lastMsgTime = 0;                   //The time (from millis()) at which last message was published
char msg[64];                           //A buffer to hold messages to be sent/have been received
char topic[32];                         //The topic in which to publish a message
int pulseCount = 0;                     //Counter for number of heartbeat pulses sent

void setup() {
  //PIN für LED & Anschalten dieser, um boot Vorgang anzuzeigen
  pinMode(D3, OUTPUT);
  digitalWrite(D3, HIGH);
  
  wifiSetup();            //WIFI-Connection
  mqttSetup();            //MQTT-Connection

  //LED kurze Blinken & ausschalten (zum Anzeigen, dass Boot-Vorgang abgeschlossen ist
  for (int i = 0; i < 4; i++){
    digitalWrite(D3, HIGH);
    delay(250);
    digitalWrite(D3, LOW);
    delay(250);
  }
}

void loop() {
  mqttLoop();
  LED();
}

void mqttCallback(char* topic, byte* payload, unsigned int length) {      //Callback function each time a message is published in any of the topics to which this client is subscribed
...
}

void mqttLoop() {
  if (MQTTclient.connected()) {
    MQTTclient.loop();              //call the main loop to check for and publish messages
  }
}

void mqttReconnect() {
  if (!MQTTclient.connected()) {
    Serial.print("\nAttempting to connect to MQTT broker at (30sek) ");
    Serial.print(mqtt_server);

    MQTTclient.connect(deviceID);
    unsigned long currentF = millis();
    unsigned long previousF = currentF;

    //der Versuch, sich neu zu verbinden soll maximal 45 Sekunden dauern, da er im Zweifel nicht 5h in dieser Schleife hängen soll. (Ich habe vor, mithilfe einer Variable im EEPROM-Speicher, bei jedem 5. Reboot hintereinander, ersteinmal eine Pause von z.B. 15min zu lassen. Denn wenn nach 5 Versuchen keine Verbindung gelingt, liegt das Problem eher am Router
    while (!MQTTclient.connected() && currentF - previousF <= 45000) {   
      delay(100);
      Serial.print("-");
      MQTTclient.connect(deviceID);
      currentF = millis();
    }
    if (!MQTTclient.connected()) {
    //Serial.print(MQTTclient.state());       //Debug Info
    Serial.write("\nMQTT-Reconnect fehlgeschlagen. Automatischer Neustart in 3 sek!\n");
    delay(3000);
    ESP.restart();
    }
    else {
      Serial.println("\nConnected to MQTT broker\n");        //Debug info
    
      //hier stehen alle subscriptions
    }
  }
}

void WiFiReconnect() {
  if (WiFi.status() != WL_CONNECTED) {
    Serial.print("\nVersuch, eine WLan Verbindung aufzustellen bei (30sek): ");
    Serial.print(ssid);

    WiFi.begin(ssid, password);
    unsigned long currentH = millis();
    unsigned long previousH = currentH;

    //der Versuch, sich neu zu verbinden soll maximal 45 Sekunden dauern, da er im Zweifel nicht 5h in dieser Schleife hängen soll
    while (WiFi.status() != WL_CONNECTED && currentH - previousH <= 45000) {
      delay(500);
      Serial.print(".");
      currentH = millis();
    }
    if (!MQTTclient.connected()) {
    //Serial.print(MQTTclient.state());       //Debug Info
    Serial.write("\nWLan-Reconnect fehlgeschlagen. Automatischer Neustart in 10 sek!\n");
    delay(10000);
    ESP.restart();
    }
    else {
      Serial.println("\nConnected to WiFi\n");                 //Debug info
      Serial.println("MQTT Verbindung wird hergestellt...");
      mqttReconnect();
    }
  }
}

void mqttSetup() {
  MQTTclient.setServer(mqtt_server, 1883);
  MQTTclient.setCallback(mqttCallback);

  Serial.print("Attempting to connect to MQTT broker at (20sek) ");
  Serial.println(mqtt_server);
  
  MQTTclient.connect(deviceID);
  unsigned long currentG = millis();
  unsigned long previousG = currentG;

  //der Versuch, sich neu zu verbinden soll maximal 20 Sekunden dauern, da er im Zweifel nicht 5h in dieser Schleife hängen soll
  while (!MQTTclient.connected() && currentG - previousG <= 20000) {
    delay(100);
    Serial.print("-");
    MQTTclient.connect(deviceID);
    currentG = millis();
  }
  if (!MQTTclient.connected()) {
    //Serial.print(MQTTclient.state());       //Debug Info
    Serial.write("\nMQTT-Verbindung fehlgeschlagen. Automatischer Neustart in 3sek!\n");
    delay(3000);
    ESP.restart();
  }
  else {
    Serial.println("\nConnected to MQTT broker");       //Debug info
  
    //hier stehen alle subscriptions
  }
}

void wifiSetup() {
  if (!Serial) {
    Serial.begin(9600);                   //Start the Serial connection
    Serial.println("\nESP gestartet");
  }

  Serial.print("Ausgewähltes Wlan-Netzwerk: ");     //Connect to the specified WiFi network
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  unsigned long currentH = millis();
  unsigned long previousH = currentH;

  Serial.print("Verbidung wird hergestellt (15sek)  ...");                    //progress while we wait to connect
  while (WiFi.status() != WL_CONNECTED && currentH - previousH <= 15000) {     //wenn keine Verbindung und weniger als 15 Sekunden vorbei: h < 15000
    delay(500);
    Serial.print(".");
    currentH = millis();
  }
  if (WiFi.status() != WL_CONNECTED) {
    Serial.write("\n Wlan Verbindung fehlgeschlagen.   Auto Restart\n");
    ESP.restart();
  }
  else {
    delay(1500);                 //give the WiFi a couple of seconds to initialize
    Serial.println();
  
    Serial.print("Verbunden! IP-Adresse: ");
    Serial.println(WiFi.localIP());
  }
}

void LED() {
  if  (WiFi.status() != WL_CONNECTED) {
    digitalWrite(D3, HIGH);
    Serial.print("\nWlan Verbindung verloren");
    WiFiReconnect();
  }
  else if (!MQTTclient.connected()) {
    digitalWrite(D3, HIGH);
    Serial.print("\nMQTT Verbindung Verloren");
    mqttReconnect();
  }
  else {
    digitalWrite(D3, LOW);
  }
}

[Michael U. (amiga)]

Hallo,

das Problem mit WLAN-Verlust und MQTT Reconnect kenne ich...
Ich hatte vor Zeiten mal einen Ansatz im Netz gefunden, den ich 
letztlich bei mir benutze.
Ich hänge mal einen Sketch von mir ran, da ist zwar noch die Ansteuerung 
einer IN-9 mit Temperaturwerten drin, das sind aber nur ein paar Zeilen.
Ich benutze aber den AsyncMQTT, PubSubClient nehme ich nur noch bei 
Sensoren, die in den DeepSleep gehen, weil mir sein teilweise 
blockierendes Verhalten erspart, nachzuschauen, ob er wirklich fertig 
ist.
Ich weiß jetzt nicht, ob es da noch Sachen bei Dir vorkommen, die ich 
hier so nicht hatte.
Ist also mehr so zum reinschauen gedacht...
PS: ESP.restart(); gibt es bei mir nie, aber nur so aus Prinzip.
Entweder habe ich im Programm was nicht berücksichtigt oder es ist 
wirklich eine Störung von Außen, die ich in Kauf nehmen muß, dann würde 
aber nur ein Hardware-Watchdog helfen, wenn er im Programm hängt, kommt 
er auch nicht zum Restart Befehl.

Gruß aus Berlin
Michael

[Bernhard S. (b_spitzer)]

Der ESP8266 braucht in der Loop (oder den darin ausgeführten Funktionen) 
irgendwo ein delay(irgendwas) oder yield(), um der WLAN-Task Rechenzeit 
abzugeben.
Mache daher mal ein delay(0) in die Loop.

[Michael U. (amiga)]

Hallo,

Bernhard S. schrieb:
> Der ESP8266 braucht in der Loop (oder den darin ausgeführten
> Funktionen)
> irgendwo ein delay(irgendwas) oder yield(), um der WLAN-Task Rechenzeit
> abzugeben.
> Mache daher mal ein delay(0) in die Loop.

loop() selbst erledigt das bei jedem Durchlauf. Ein yield(); muß dort 
hin, wo es länger dazernde Blockierungen gibt, ich habe seine 
aufgerufenen Funktionen noch nicht komplett durchgeschaut.
Wenn ein Durchlauf der loop immer schnell genug ist, braucht kan es 
nicht.

...
while (digitalRead(Pin) == HIGH)
{
  yield();
}
...

Hier wäre ein yield(); Pflicht, wenn der Pin länger auf High sein kann, 
z.B. Warten auf einen Tastendruck.

Gruß aus Berlin
Michael

[Stefan F. (Gast)]

Für den Wiederaufbau der WLAN Verbindung muss man gar nichts 
programmieren, das macht die Basis-Firmware des ESP8266 von ganz 
alleine.

Was den MQTT Anteil angeht: Das könnte es anders sein.

[Michael U. (amiga)]

Hallo,

Stefan F. schrieb:
> Für den Wiederaufbau der WLAN Verbindung muss man gar nichts
> programmieren, das macht die Basis-Firmware des ESP8266 von ganz
> alleine.

Prinzipiell ja, es gibt aber Umstände, wo er nicht will. Hier 
(vielleicht nur in Verbindung mit meinem Router), als Beispiele: 
längerer WLAN Ausfall, Kanalwechsel. Nicht immer, aber es passiert. 
Natürlich kann man dann eben einen Restart auslösen, teilweise laufen 
aber auf den ESPs Sachen, wo ich mir dann extra den letzten Zustand 
merken müßte usw.

> Was den MQTT Anteil angeht: Das könnte es anders sein.
Da passiert folgendes: Der ESP8266 meldet WL_CONNECTED sobald die 
Verbindung zum Router steht. Da hat er aber noch keine IP vom DHCP. Wenn 
jetzt bereits das MQTT connect folgt, geht das schief.
Da hilft dann der Event onWifiConnect(const WiFiEventStationModeGotIP& 
event); weiter, der triggert, wenn eine gültige IP vom DHCP angekommen 
ist.
Es wird immer von der Anwendung abhängen, welchen Weg man gehen will.
zumindest habe ich seitdem keine hängenden ESP8266 mehr im Netz gehabt.

Gruß aus Berlin
Michael

[Stefan F. (Gast)]

Michael U. schrieb:
> prinzipiell ja, es gibt aber Umstände, wo er nicht will.

Dann hast du wohl eine Fehlerhafte Firmware Version.

Ich habe einen ESP8266 seit 4 Jahren im Dauerbetrieb. Jede Nacht schalte 
ich meinen Router aus und zwischendurch bricht das WLAN Netz auch 
tagsüber wegen Störungen (von woher weiß der Teufel) zusammen.

Bisher hat das ESP Modul die Verbindung immer von alleine neu aufgebaut. 
Wirklich immer. 100%

Ich benutze wegen der Zuverlässigkeit bewusst den alten Arduino Core 
2.3.0, welcher (soweit ich weiß) auf dem SDK 1.5.4 basiert.

[Klausi (Gast)]

Danke schonmal für eure Antworten.
Ja, grundsätzlich verbindet sich der ESP zwar automatisch wieder mit dem 
WLAN, ich will aber verhindern, dass er sich bei gestörter Verbindung in 
irgendwelchen loops verfängt.

Fällt zum Beispiel das WLAN aus, ist natürlich sowohl die WLAN 
Verbindung ald auch die MQTT Verbindung weg.
Ich will dann eben eine geregelte Reconnection.

Und wenn längere Zeit keine Chance auf einen erfolgreichen Aufbau der 
Verbindung steht, soll er halt - anstatt Minuten-/stundenlang einen 
reconnect zu versuchen - einen Neustart und oder eine Pause machen und 
sich eben nicht damit selbst blockieren.