I2C Daten im Intervall Abrufen

[Patrick (Gast)]

Hallo,

ich habe ein Problem mit mein Kleinen Projekt.

Dabei soll jede Sekunde der Aktuelle Strom von einem INA219 abgerufen 
werden, und per Serielle Schnittstelle ausgegeben werden.

Jedoch sobald ich die Lese Routine über die ISR ausführen möchte hängt 
sich der Controller auf.

Lasse ich die Routine im Loop laufen funktioniert sie Fehlerfrei. Auch 
wenn ich zusätzlich in der ISR was anderes mache läuft der LOOP und die 
ISR problemlos.

Kann mir jemand dabei helfen.

#include <Wire.h>

#define Add_Current0 0x40
#define Add_Current1 0x41

#define R_Shunt0 0.1
#define R_Shunt1 0.1

#define Acc0 0.0001   // maximum = max Current/2^15
#define Acc1 0.0001

float data = 0;
void setup() 
{
  Wire.begin();
  Serial.begin(250000);
 
  current_write_Config(Add_Current0,0x399F);
  current_write_Config(Add_Current1,0x399F);

  current_write_Calibration(Add_Current0,R_Shunt0,Acc0);
  current_write_Calibration(Add_Current1,R_Shunt1,Acc1);

  Timer_Setup();
 
}
void loop() 
{
    
    

}

ISR(TIMER1_COMPA_vect)
{

  data = current_get_Current (Add_Current1,Acc1);
    Serial.println(data,4);
  
}

void current_write_Config (byte Addr, short data)
{
  
  Wire.beginTransmission(Addr);
  Wire.write(byte(0x00));
  byte transmit = data >> 8;
  Wire.write(transmit);
  
  transmit = data;
  Wire.write(transmit);
  
  Wire.endTransmission();
  
}

void Timer_Setup()
{
  TCCR1A = 0;
  TCCR1B = 0;
  OCR1A = 62500; //1Hz
  TCCR1B |= (1<<WGM12)| (1<<CS12);
  
  TIMSK1 |= (1<<OCIE1A);
    
}
void current_write_Calibration (byte Addr, float shunt, float acc)
{
  
  Wire.beginTransmission(Addr);
  Wire.write(byte(0x05));
  short data = trunc(0.04096/(acc*shunt));
  
  byte transmit = data >> 8;
  Wire.write(transmit);
  
  transmit = data;
  Wire.write(transmit);
  
  Wire.endTransmission();
  
}

float current_get_Current (byte Addr,float acc)
{
  
  Wire.beginTransmission(Addr); 
  Wire.write(byte(0x04));      
  Wire.endTransmission(); 
  short reading = 0;

   Wire.requestFrom(Addr, 2);
  
  if (2 <= Wire.available()) { // if two bytes were received
   reading = Wire.read();  // receive high byte (overwrites previous reading)
   reading = reading << 8;  // shift high byte to be high 8 bits
   reading |= Wire.read(); // receive low byte as lower 8 bits
  }
   
   float current = reading *acc ;
   
   return(current);
}

[leo (Gast)]

Patrick schrieb:
> ISR(TIMER1_COMPA_vect)
> {
>   data = current_get_Current (Add_Current1,Acc1);
>     Serial.println(data,4);

Mindestens 2 Fehler:
- data muss volatile sein
- Serial.println in einer ISR ist verboten

leo

[Jens W. (jensw)]

wenn du die einfach in der Loop laufen lässt, wie schnell kommen denn 
dann die Werte?
Viel schneller als 1s oder langsamer?
Und wie ist es mit dem Timer?
Läuft der immer weiter? Oder muss der in der ISR einfach neu gestartet 
werden?
Sprich, ließt er einmal die Werte aus und stoppt dann? (Weil der Timer 
stehen geblieben ist).

Grüße, Jens

[Patrick (Gast)]

Also er blibt im Timer hängen.

Wenn ich dort nur mir die millis anzeigen lasse kommen die im Sekunden 
Takt.

das eine Print Funktion nix in der ISR zu suchen hat ist mir klar, war 
jetzt nur zum debuggen.

Die print Funktion soll später im Loop und nur ausgeführt werden, wenn 
ich neue Daten über die i2C empfangen habe.

[Patrick (Gast)]

hab den Datentyp geändert mit "volatile" geändert.

jedoch bleibt das Programm weiter vor der Print Funktion hängen, so das 
diese nicht ausgeführt wird.

[Patrick (Gast)]

Hab es auch mal so versucht, auch hier wird die Print funktion nicht 
ausgeführt.

Die unterprogramme welche unverändert sind habe ich mal jetzt nicht 
mitgesendet.

#include <Wire.h>

#define Add_Current0 0x40
#define Add_Current1 0x41

#define R_Shunt0 0.1
#define R_Shunt1 0.1

#define Acc0 0.0001   // maximum = max Current/2^15
#define Acc1 0.0001

volatile float data = 0;
volatile byte x = 0;
void setup() 
{
  Wire.begin();
  Serial.begin(250000);
 
  current_write_Config(Add_Current0,0x399F);
  current_write_Config(Add_Current1,0x399F);

  current_write_Calibration(Add_Current0,R_Shunt0,Acc0);
  current_write_Calibration(Add_Current1,R_Shunt1,Acc1);

  Timer_Setup();
 
}
void loop() 
{
    
    if (x==1)
    {
      Serial.println(data,4);
      x=0;
    }

}

ISR(TIMER1_COMPA_vect)
{

  data = current_get_Current (Add_Current1,Acc1);
  x=1;  
  
}

[Patrick (Gast)]

hab des rätsels Lösung.

Die Wire.h benötigt ebenfalls Interrupt befehle welche in der ISR 
deaktiviert sind.
habe jetzt zu beginn der ISR die Interrupts per sei(); aktiviert und es 
läuft.

keine schöne lösung, funktioniert aber schonmal.

falls jemand ein eleganteren vorschlag hat gerne her damit.

[MinMax (Gast)]

Weshalb muss die Abfrage der Daten in der ISR stattfinden? Setze in der 
ISR einfach ein Flag und werte es in der Loop aus.

Und überhaupt, weshalb für diesen Zweck einen Timer Interrupt? Bei einer 
Periode von 1 Sekunde kann das auch ein millis() Vergleich in der Loop 
erledigen.

[Patrick (Gast)]

wichtig ist, das der Daten abruf im sekunden intervall passiert. Da noch 
einiges mehr im Code später passiert, dann es sein das ein kompletter 
durchlauf länger dauert als eine sekunde.

[leo (Gast)]

Patrick schrieb:
> wichtig ist, das der Daten abruf im sekunden intervall passiert. Da noch
> einiges mehr im Code später passiert,

Verwende einen Taskmanager statt der ISR, e.g.
https://github.com/prampec/arduino-softtimer
https://github.com/arkhipenko/TaskScheduler
usw.

leo

[Michael M. (michael89)]

Hallo,

Nimm doch die Struktur aus dem Arduino Beispiel "blink without delay".

unsigned long millis_1s =0;

void loop(){

 if( millis() - millis_1s >= 1000){
 millis_1s+=1000;

 // Hier was du jede Sekunde ausgeführt haben willst

 }

 // Restlicher Code
}

Gruß

[Delay me not (Gast)]

Michael V. schrieb:
> Nimm doch die Struktur aus dem Arduino Beispiel "blink without delay".

Er hat in seiner loop() noch andere Programmteile, die länger als 1 
Sekunde laufen können (vermutlich wegen großzügigem Delay-Einsatz)

---> loop umstrukturieren, dass ein durchlauf wieder nur eine sache von 
wenigen msec ist.

Eine Statemachine kann dabei helfen.