ATTiny85, Timer 1 PWM an PB1

[T. (Gast)]

Hallo in die Runde,

ich bin schon längere Zeit stiller Mitleser, jetzt habe ich auch mal 
eine konkrete Frage/ ein konkretes Problem:

Bei Versuchen mit einem ATTiny85 versuche ich zu Zeit, PWM zum laufen zu 
bringen.
Ich habe Timer 1 auf ~3,9 kHz gesetzt:
cli();
  TCCR1 = TCCR1 & 0b11110000 | ((0 << CS13) | (1 << CS12) | (0 << CS11) 
| (0 << CS10));
  sei();

Nun setzte ich folgend PB4 auf 127 (ca. 50/50 an/aus)
// connect pwm to pin on timer 1, channel B
pinMode(4, OUTPUT);
sbi(GTCCR, COM1B1);
OCR1B = 127; // set pwm duty

Das funktioniert. Ebenso, wenn ich Timer 0 (mit seinen weiterhin 490 Hz) 
an PB1 hänge:
pinMode(1, OUTPUT);
sbi(TCCR0A, COM0B1);
OCR0B = 127; // set pwm duty

Das funktioniert auch. Jedoch hätte ich am PB1 lieber den Timer 1 
genutzt, diese alternative Belegung ist ja im Datenblatt erläutert.

Entsprechend habe ich folgenden Code:
pinMode(1, OUTPUT);
sbi(TCCR1, COM1A1);
OCR1A = 127; // set pwm duty

Das funktioniert aber nicht. Habt ihr eine Idee warum? Möglicherweise 
habe ich noch etwas vergessen.

Danke im Voraus

[S. Landolt (Gast)]

Wie sieht das vollständige Programm aus?

[T. (Gast)]

Ich schreibe das in der Arduino IDE:

#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))

void setup() {
  // Timer 1 auf 3906 Hz (PWM-Ausgänge 1 und 4)
  cli();
  TCCR1 = TCCR1 & 0b11110000 | ((0 << CS13) | (1 << CS12) | (0 << CS11) | (0 << CS10));
  sei();

  pinMode(1, OUTPUT);
  sbi(TCCR0A, COM0B1);
  //cbi(TCCR0A, COM0B0);
  OCR0B = 127; // set pwm duty

  while(1);
}

Den mittleren Block ersetze ich entsprechend. Ich habe zur Fehlersuche 
im Prinzip alles außer dieser Funktion entfernt.

[S. Landolt (Gast)]

>   OCR0B = 127; // set pwm duty

Ich denke, das sollte OCR0A sein.

[S. Landolt (Gast)]

Entschuldigung, das war Unsinn von mir.

Ich denke, wir reden hier vom Timer1?

[T. (Gast)]

Ja:

#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))

void setup() {
  // Timer 1 auf 3906 Hz (PWM-Ausgänge 1 und 4)
  cli();
  TCCR1 = TCCR1 & 0b11110000 | ((0 << CS13) | (1 << CS12) | (0 << CS11) | (0 << CS10));
  sei();

  pinMode(1, OUTPUT);
  sbi(TCCR1, COM1A1);
  OCR1A = 127; // set pwm duty

  while(1);
}

Das funktioniert nicht, PB1 bleibt aus.

[S. Landolt (Gast)]

Das wundert mich: dies, in Assembler, läuft hier:

 sbi    DDRB,1
 puti   TCCR1,(1<<CTC1)|(1<<PWM1A)|(1<<COM1A0) |(1<<CS11)
 puti   OCR1A,127

Ich sehe jetzt keinen wesentlichen Unterschied zu Ihrem.

[S. Landolt (Gast)]

Ah, doch, TCCR1 steht nach Reset auf 0, folglich ist

TCCR1 = TCCR1 & irgendetwas

immer 0.

[S. Landolt (Gast)]

in C:

#include <avr/io.h>
int main(void)
{
  TCCR1 = (1<<CTC1)|(1<<PWM1A)|(1<<COM1A0) |(1<<CS12);
  DDRB = (1<<PB1);
  OCR1A = 127;
    while (1) 
    {
    }
}

[T. (Gast)]

Was bedeutet das jetzt für mich?
So ganz habe ich den letzten Kommentar auch nicht verstanden :)

[T. (Gast)]

S. Landolt schrieb:
> in C:#include <avr/io.h>
> int main(void)
> {
>   TCCR1 = (1<<CTC1)|(1<<PWM1A)|(1<<COM1A0) |(1<<CS12);
>   DDRB = (1<<PB1);
>   OCR1A = 127;
>     while (1)
>     {
>     }
> }

Mein letzter Beitrag bezog sich auf den vorletzten von Ihnen. Danke, ich 
werde das testen und morgen Feedback geben.

[S. Landolt (Gast)]

Noch ergänzend: bei CTC müsste eigentlich OCR1C zugewiesen werden (um 
die Frequenz der PWM einzustellen; folglich größer als OCR1A); dass es 
hier trotzdem funktioniert, liegt daran, dass bei Reset OCR1C=255 (0xFF) 
gesetzt ist.

[T. (Gast)]

Einen schönen guten Morgen,

danke S. Landolt, es funktioniert jetzt. Parallel habe ich den Timer 1B 
auch so angepasst, der lief zwar vorher schon, aber jetzt ist es 
einheitlich.

Programm jetzt (Arduino IDE):

#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))

void setup() {
  cli();
  TCCR1 = ((1<<CTC1) | (1<<PWM1A) | (1<<CS12)); //(1<<COM1A1) | 
  GTCCR = ((1<<PWM1B)); // | (1<<COM1B1));
  sei();
}

void loop() {
  /*
  * Abschnitt um Duty-Cycle zu ermitteln
  */
  analogWriteC(pb1, value_a);
  analogWriteC(pb4, value_b);
}

void analogWriteC(uint8_t pin, int val) {
  pinMode(pin, OUTPUT);
  if (pin == 1) {       // für Pin 1
    if (val <= 0) {     // aus 
      digitalWrite(pin, LOW);
      cbi(TCCR1, COM1A1);     // Timer trennnen
    } else if (val >= 255) {  // an
      digitalWrite(pin, HIGH);
      cbi(TCCR1, COM1A1);     // Timer trennnen
    } else { // pwm
      sbi(TCCR1, COM1A1);     // Timer verbinden
      OCR1A = val;            // Duty-Cycle setzten
    }
  } else if (pin==4) { // ebenso für Pin 4
    if (val <= 0) {
      digitalWrite(pin, LOW);
      cbi(GTCCR, COM1B1);
    } else if (val >= 255) {
      digitalWrite(pin, HIGH);
      cbi(GTCCR, COM1B1);
    } else {
      sbi(GTCCR, COM1B1);
      OCR1B = val;
    }
  }
}

Danke!

[Karl M. (Gast)]

Sorry,

einen Timer 1B gibt es nicht!

Wie kommt man darauf?

[S. Landolt (Gast)]

> einen Timer 1B gibt es nicht!

Es gibt den Timer1-PulseWidthModulatorB.