Gnuplot: Mehrere plots (multiplot) über gleicher x-Achse?

[Johann L. (gjlayde)]

Hi, mit Gnuplot v4.4 möchte ich ein multiplot für 1:2 und 1:3 für 
folgende Daten machen:

0 -1.000673e+000
1 -5.563919e-001 4.442806e-001
2 -2.858316e-001 2.705603e-001 -1.737204e-001
3 -5.589447e-002 2.299372e-001 -4.062311e-002
4 1.363203e-001 1.922148e-001 -3.772237e-002
5 3.072147e-001 1.708944e-001 -2.132036e-002
6 4.645879e-001 1.573731e-001 -1.352128e-002
7 6.128868e-001 1.482989e-001 -9.074243e-003
8 7.549088e-001 1.420221e-001 -6.276821e-003
9 8.924935e-001 1.375846e-001 -4.437459e-003
10 1.026892e+000 1.343987e-001 -3.185958e-003
11 1.158978e+000 1.320857e-001 -2.313006e-003
12 1.289371e+000 1.303928e-001 -1.692896e-003
13 1.418517e+000 1.291463e-001 -1.246417e-003
14 1.546742e+000 1.282246e-001 -9.217196e-004
15 1.674282e+000 1.275408e-001 -6.838224e-004

Das Resultat sieht ziemlich hässlich und unleserlich aus, siehe Anhang.

1) Beide Spalten sollen die 1. Spalte als x-Achse verwenden, und zwar 
mit gleicher Skalierung etc.

2) Die Wertebereiche sind unterschiedlich, daher möchte ich die Bemaßung 
für die 2. Spalte (y1-Achse) links und die Bemaßung für die 3. Spalte 
(y2-Achse) rechts im Plot haben.

Mein Skript sieht momentan so aus:

Data = "q10.data"

Form = "png"

call "size.gplot" Data

#set xrange [min_x:max_x]
#set x2range [min_x:max_x]

set terminal Form size 640,480
set output "q10." . Form
set multiplot

#show autoscale
set autoscale keepfix
#set autoscale xfixmin
#set autoscale xfixmax
#set autoscale x2fixmin
#set autoscale x2fixmax
#show autoscale

plot [min_x:max_x] Data using 1:2 with lines title "quality p10" axes x1y1
plot [min_x:max_x] Data using 1:2 title "quality p10" axes x1y1

plot [min_x:max_x] Data using 1:3  lc "#000000" with lines axes x1y2

 
*size.gplot*

# Sets:
# size_x ,min_x, max_x,
# size_y, min_y, max_y.

# Dummy plot to get statistical properties without
# having "stats" command like with v4.4.4.

set terminal unknown
plot $0 u 1:2

min_x = GPVAL_DATA_X_MIN
max_x = GPVAL_DATA_X_MAX
min_y = GPVAL_DATA_Y_MIN
max_y = GPVAL_DATA_Y_MAX

size_x = max_x - min_x
size_y = max_y - min_y

Laut Doku sollte "xfixmin" "x2fixmin" etc. zu gleicher Skalierung der 
beiden x-Achsen führen.  Tut's aber nicht...

Wie macht man das richtig?

[Tobias P. (hubertus)]

Du musst doch dazu keinen multiplot verwenden. Du kannst auch

plot Data using 1:2 w l ax x1y1, Data using 1:3 w l ax x1y2

dann wird nur ein einzelner Plot erzeugt. Beispiel siehe Anhang.

reset

set y2tics in

set grid

set bmargin 4
set label 1 at graph 0.5, char 1 'xlabel' center

set lmargin 15
set label 2 at graph -0.12, graph 0.5 'y1label' right

set rmargin 30
set label 3 at graph 1.12, graph 0.5 'y1label' left

set key reverse Left
set key samplen 2
set key spacing 1.5
set key at graph 1.2, 1 left

plot 'data.txt' u 1:2 w lp pt 7 ps 1 ax x1y1 title 'Daten', \
     ''         u 1:3 w lp pt 7 ps 1 ax x1y2 title 'andere Daten'

allerdings würde ich nicht 2 y-Achsen benutzen. Obwohl man es kann, muss 
man immer tierisch aufpassen, dass die Ticks links und rechts zueinander 
passen, weil es sonst einfach hässlich wie die Nacht aussieht und das 
Gitter nirgends passt. Daher würde ich in der Tat in Erwägung ziehen 
einen Multiplot zu verwenden, wie im 2. Beispiel.

reset

set grid

set bmargin 4

set lmargin 15

set rmargin 18

set key reverse Left
set key samplen 2
set key spacing 1.5
set key at graph 1, 1 left

set multiplot layout 2,1

set label 1 at graph 0.5, graph -0.35 'xlabel' center
set label 2 at graph -0.12, graph 0.5 'y1label' right
plot 'data.txt' u 1:2 w lp pt 7 ps 1 title 'Daten'

set label 2 at graph -0.12, graph 0.5 'other' right
plot 'data.txt' u 1:3 w lp pt 7 ps 1 title 'andere Daten'

unset multiplot

[Johann L. (gjlayde)]

Tobias P. schrieb:
> Du musst doch dazu keinen multiplot verwenden. Du kannst auch
>
>

> plot Data using 1:2 w l ax x1y1, Data using 1:3 w l ax x1y2
>

>
> dann wird nur ein einzelner Plot erzeugt. Beispiel siehe Anhang.

Danke für den Tipp!  Damit sieht es schon viel besser aus.

> allerdings würde ich nicht 2 y-Achsen benutzen. Obwohl man es kann, muss
> man immer tierisch aufpassen, dass die Ticks links und rechts zueinander
> passen,

Ist kein Problem, da ich in der Grafik kein Gitter haben will.  Es es 
nur eine Übersichtsgrafik wo ich die Bemaßung brauche bzw. sehen will.

> weil es sonst einfach hässlich wie die Nacht aussieht und das
> Gitter nirgends passt. Daher würde ich in der Tat in Erwägung ziehen
> einen Multiplot zu verwenden, wie im 2. Beispiel.

Das kann ich bestimmt auch mal gebrauchen; momentan ist's in 1 Plot 
übersichtlicher.

Wie kommst du auf all die magischen Zahlen?  Ist das einfach 
ausprobieren oder kann man die berechnen?

[Tobias P. (hubertus)]

Johann L. schrieb:
> Wie kommst du auf all die magischen Zahlen?  Ist das einfach
> ausprobieren oder kann man die berechnen?

einige davon sind ausprobiert.

Also

set key samplen 2
set key spacing 1.5
set key at graph 1, 1 left
set key reverse Left

mach ich immer gleich, weil es meiner Meinung nach hübscher aussieht als 
der Defaultwert, und weil ich die Legende immer oben links ausserhalb 
des Plots will. Die Legende ist mit den 3 obigen Befehlen bombenfest 
verankert und immer gleich.

set bmargin 4
set lmargin 15
set rmargin 18

ist immer ein wenig ein herum pröbeln. Ich mach die Achsen bei 
Diagrammen immer DIN461-formatiert, wegen der Legende und wegen 
allfälliger Einheiten oder Spezialsymbolen sind die Achsenbeschriftungen 
immer ein wenig anders in der Breite bzw. Höhe. Ich habe da leider noch 
keine befriedigende Lösung gefunden, die zuverlässig funktioniert.

set multiplot layout 2,1

das ist ja klar (2 Zeilen, 1 Spalte).

set label 1 at graph 0.5, graph -0.35 'xlabel' center
set label 2 at graph -0.12, graph 0.5 'y1label' right
...
set label 2 at graph -0.12, graph 0.5 'other' right

ich mache die Achsenbeschriftungen immer mit "set label" und nicht 
"xlabel" oder "ylabel", weil vor einigen Monaten in gnuplot eine 
Änderung gemacht wurde, die mir alte Plots zerschossen hat und ich 
musste dann jeden Plot händisch anfassen. Es hatte irgendwas mit der 
Ausrichtung der x/y-Labels zu tun, die gnuplot automatisch macht. Auf 
jeden Fall hat da was nicht richtig funktioniert, und seither mache ich 
die Labels händisch. graph 0.5 bedeutet, dass das Label mittig zum 
Graphen positioniert wird (beim x-Label ja sinnvoll, deshalb ist es auch 
zentriert). Die -0.35 findet man durch herum pröbeln ;-) dasselbe fürs 
y-Label.

Man könnte übrigens auch schreiben

set label 1 at graph 0.5, graph -0.35 'xlabel' center
set label 2 at graph -0.12, graph 0.5 'y1label' right
...
set label 2 'other' right

womit man die Positionsangabe beim 2. mal eigentlich sparen kann, nur 
der Text muss geändert werden.

Ich habe mir eine gnuplotsetup.gp zusammen gebastelt, die so aussieht

set linetype 1 lw 2 lc rgb '#0072bd' # blue
set linetype 2 lw 2 lc rgb '#d95319' # orange
set linetype 3 lw 2 lc rgb '#edb120' # yellow
set linetype 4 lw 2 lc rgb '#7e2f8e' # purple
set linetype 5 lw 2 lc rgb '#77ac30' # green
set linetype 6 lw 2 lc rgb '#4dbeee' # light-blue
set linetype 7 lw 2 lc rgb '#a2142f' # red

set palette defined (\
0 '#352a87',\
1 '#0363e1',\
2 '#1485d4',\
3 '#06a7c6',\
4 '#38b99e',\
5 '#92bf73',\
6 '#d9ba56',\
7 '#fcce2e',\
8 '#f9fb0e')

set style line 1 lw 3
set style line 2 lw 3
set style line 3 lw 3
set style line 4 lw 3
set style line 5 lw 3
set style line 6 lw 3
set style line 7 lw 3

set style line 100 lw 1 lc rgb 'black' dt '.'
set grid ls 100 front

set border 15 lw 2 front

set key at graph 1,1 left
set key reverse Left
set key samplen 2
set key spacing 1.5

und die muss ich dann nur noch einmal laden:

laod 'gnuplotsetup.gp'
plot sin(x) title 'funky stuff'

dann sieht der Plot schon defaultmässig etwas hübscher aus (u.a. will 
ich immer ein Gitter und die Matlab-Farben verwenden, und eben ein paar 
Ausrichtungen an der Legende korrigieren).

Im Anhang ein Beispiel wie ich das dann immer mache. Dass sind dann nur 
noch wenige Zeilen, weil ich nur die Labels und Ränder richtig setzen 
muss und natürlich noch der eigentliche Plotbefehl. Aber so kann man 
sich ein wenig Schreibarbeit sparen :-)