Erkennen von Videoaufnahme anhand LED-Blinken

[Helge (Gast)]

Hallo.

ich möchte an einer Kamera überprüfen, ob sie aufnimmt. Hierzu habe ich 
die Led der Kamera angezapft, die bei Aufnahme blinkt. Das funktioniert 
soweit.
Die Led blinkt im 1.Sekunden Takt. Bleibt das blinken aus, wird 
is_recording = false gesetzt.

Nun kommt allerdings als Schweirigkeit dazu, dass wenn das Ladekabel an 
der Kamera hängt, die Led ebenfalls blinkt.
Ich müsste jetzt herausfinden, ob die LED mindestens zweimal blinkt und 
dann erst is_recording = true; setzen. Momentan wird es sobald einmal 
Blinken erkannt wird, gesetzt.

Kann mir jemand einen Anstoß geben wie man das lösen könnte?
Ich sitze gerade davor und sehe den Wald vor lauter Bäumen nicht..

ich müsste irgendwie einen zähler inkrementieren und dann auswerten zb
if (blinken>2) is_recording=true

void loop_check_is_recording() {
  if (digitalRead(PIN_KAMERA_STATUSLED) == 0) {
    is_recording = true;
    lcis_previousMillis = millis();
  }
  if (millis() - lcis_previousMillis >= 1500) {
    is_recording = false;
  }
}

[Achim M. (minifloat)]

Du musst für einmal Blinken die Flanke LED-aus zu LED-an als Referenz 
hernehmen. Dazu mit dem im letzten Zyklus erfassten Zustand vergleichen.

Damit kannst du deinen Blinkzähler "blinken" inkrementieren, wenn er 
noch nicht 3 erreicht hat.

Timeout geht wie bisher, nur dass er auch "blinken" nullt. Danach dann 
wie von dir vermutet,

Helge schrieb:
> if (blinken>2) is_recording=true

...fertig ist die Laube.
mfg mf

[Helge (Gast)]

Hallo Achim,

danke für deine Erläuterung. Ich hatte gehofft, dass es damit klickt 
macht bei mir. aber ich bin noch nicht dahinter gestiegen wie du meinst 
mit der Flanke?
Könntest du mir da mit einem kurzem Pseudocode auf die Sprünge helfen?

Ich muss dazu noch sagen, dass digitalRead(PIN_KAMERA_STATUSLED) == 0 
bedeutet, dass die Led hier an wäre. Der Eingang ist per pull-up hoch 
gezogen und wenn die Led der Kamera leuchtet wird er auf GND gezogen.

Grüße und schöne Weihnachten
Helge

[Rolf M. (rmagnus)]

Helge schrieb:
> Hallo Achim,
>
> danke für deine Erläuterung. Ich hatte gehofft, dass es damit klickt
> macht bei mir. aber ich bin noch nicht dahinter gestiegen wie du meinst
> mit der Flanke?

Aktuell prüfst du nur den Status aus oder an. Du musst den Wechsel von 
aus nach an erkennen. Dazu musst du dir den vorherigen Zustand der LED 
merken und mit dem aktuellen vergleichen. Immer wenn der vorherige "aus" 
war und der neue nicht, startet ein neues Blink-Intervall. Damit kannst 
du dann auch ganz einfach zählen, wie oft geblinkt wurde.

[Achim M. (minifloat)]

Vielleicht so?

int led_old = HIGH; // normally, low-active LED is off
int blinken = 0;
unsigned long lcis_previousMillis = 0;
bool is_recording = false;

void loop_check_is_recording()
{
  int led_new = digitalRead(PIN_KAMERA_STATUSLED);

  // check for negative edge on LED-pin
  if(  (led_old == HIGH)
     &&(led_new == LOW ))
  {
    // count negative edges
    // limit blink counts to prevent overflow
    if(blinken < 2)
    {   
      blinken++;
    }
    
    // store timestamp of neg. edge
    lcis_previousMillis = millis();
  }

  // if there was no neg. edge the last 1.5sec ...
  if (millis() - lcis_previousMillis >= 1500)
  {
    // ... there's no blinken
    blinken = 0;
  }

  // of there was more than one blink...
  if (blinken > 1)
  {
    // ... we're recording ...
    is_recording = true;
  }
  else
  {
    // ... otherwise we're not recording
    is_recording = false;
  }

  // store LED-pin status for next cycle
  led_old = led_new;
}

mfg mf

[Achim M. (minifloat)]

Besser:

int led_old = HIGH; // normally, low-active LED is off
int blinken = 0;
unsigned long lcis_previousMillis = 0;
bool is_recording = false;

void loop_check_is_recording()
{
  int led_new = digitalRead(PIN_KAMERA_STATUSLED);

  // check for negative edge on LED-pin
  if(  (led_old == HIGH)
     &&(led_new == LOW ))
  {
    // count negative edges
    // limit blink counts to prevent overflow
    if(blinken < 2)
    {   
      blinken++;
    }
    
    // store timestamp of neg. edge
    lcis_previousMillis = millis();
  }
  else if (millis() - lcis_previousMillis >= 1500)
  {
    // if there was no neg. edge the 
    // last 1.5sec there's no blinken
    blinken = 0;
  }
  else
  {
    // nothing to do
  }

  // if there was more than one blink...
  if (blinken > 1)
  {
    // ... we're recording ...
    is_recording = true;
  }
  else
  {
    // ... otherwise we're not recording
    is_recording = false;
  }

  // store LED-pin status for next cycle
  led_old = led_new;
}

[Helge (Gast)]

Hallo,

danke euch Beiden. Das sieht gut aus, werde das gleich mal einbauen und 
testen.Warum ist das zweite Bespiel noch besser?

[Achim M. (minifloat)]

Helge schrieb:
> Warum ist das zweite Bespiel noch besser?

Wenn eine Flanke erkannt wurde, muss ich im selben Zyklus nicht den 
Timeout prüfen...

mfg mf