Attiny412 Arduino megatinyCore sleepMode

[DerNeue (Gast)]

Hallo zusammen,

ich mache gerade die ersten Schritte mit dem Attiny412 und der 
megaTinyCore in Arduino.

Ich habe leider ein Problem mit dem "aufwachen" aus dem Sleep-Mode mit 
einer steigenden Flanke an einem Pin.

https://cdn.tindiemedia.com/images/resize/PrhuQ78RWdU0AKZwkpfWuOkc2gk=/p/full-fit-in/2336x1752/i/77443/products/2019-08-25T00%3A37%3A05.079Z-ATtiny_xy2.png?1606306133

An Pin 2 (also PA1) habe ich einen Taster. Dieser ist an der einen Seite 
an 5V und an der anderen Seite an Pin 2 (PA1) angeschlossen.

Normal sollte ja beim drücken der Taste ein High anliegen und damit der 
Mikrocontroller aufwachen. Doch leider macht er das nicht.
Später würde ich gerne auch noch einen Wert eines Sensors mittels ADC 
auslesen, aber da bis jetzt nicht einmal das aufwachen klappt, habe ich 
den Code mal auf das Minimum reduziert.

Die Pixel LEDs hängen an der 5V Versorgungsspannung und GND hängt am 
"Collector" eines NPN Transistor. Die Basis mit 10kOhm an Pin 1 (PA7) 
und der Emitter ist mit Masse verbunden.
Die Datenleitung ist mit einem 300Ohm widerstand mit Pin 3 (PA2) 
verbunden.

In Zeile 28, habe ich es eigentlich mit RISING versucht, aber das klappt 
leider nicht. Mit BOTHEDGES klappt es ein paar mal, dann hängt sich der 
uC irgendwie auf und ich bekomme Ihn nicht mehr geweckt.
Zeile 29 benötige ich zum ausschalten der Pixel LEDs. Diese verbinden 
sich sonst über die Datenleitung mit der Masse und ich benötige zu viel 
Strom.

Ifrgendwie bin ich ratlos. Ich suche schon die ganze Zeit im Internet 
aber finde leider nichts gescheites.

Hier habe ich mich schon eingelesen:
http://www.technoblogy.com/show?2RA3
https://github.com/SpenceKonde/megaTinyCore/blob/master/megaavr/extras/PowerSave.md

#include <tinyNeoPixel.h>
#include <avr/sleep.h>

// Which pin on the Arduino is connected to the NeoPixels?
#define PIN            3
// How many NeoPixels are attached to the Arduino?
#define NUMPIXELS      3
tinyNeoPixel strip = tinyNeoPixel(NUMPIXELS, PIN, NEO_GRBW + NEO_KHZ800);

ISR(PORTA_PORT_vect) {
  PORTA.INTFLAGS = PORT_INT1_bm;
}

void setup() {
   pinMode(4, INPUT_PULLUP);
   PORTA.PIN1CTRL = PORT_PULLUPEN_bm;
   delay(100);
   strip.begin();

   set_sleep_mode(SLEEP_MODE_PWR_DOWN);
   sleep_enable();
}

void loop() {
   LightLEDColor(100, 0, 0, 0);
   delay(5000);
   LightLEDColor(0,0,0,0);
   PORTA.PIN1CTRL = PORT_PULLUPEN_bm | PORT_ISC_BOTHEDGES_gc;
   digitalWrite(3, HIGH);
   pinMode(3,INPUT);
   sleep_cpu();
   strip.begin();
   PORTA.PIN1CTRL = PORT_PULLUPEN_bm; 
   strip.begin();   
}

void LightLEDColor(int R, int G, int B, int W)
{
   for (int i = 0; i < NUMPIXELS; i++) {
    strip.setPixelColor(i, strip.Color(R, G, B, W));
    delay(1);
  }
  strip.show();
}

[Nummer E. (ritaripp)]

<An Pin 2 (also PA1) habe ich einen Taster. Dieser ist an der einen 
Seite
an 5V und an der anderen Seite an Pin 2 (PA1) angeschlossen>

PA1 liegt durch Pullup auf Vcc . Leg den Taster auf Masse.

Unbenutzte Pins ziehen im Deepsleep 1mA, also abschalten:
PORTA.PINxCTRL =4;    //INPUT_DISABLE  ,Digital input buffer disabled

[DerNeue (Gast)]

Hallo,
danke für den Hinweis. Habe es ausprobiert mit Taster auf GND und das 
hat auch funktioniert.
Dann habe ich noch weiter versucht und habe es nochmal mit dem Taster an 
5V versucht.
So hat das dann auch geklappt. Änderung in Zeile 23.

Jetzt wollte ich zum ausprobieren mal einen AM312 Bewegungsmelder als 
Auslöser verwenden.
https://i.stack.imgur.com/qWMTw.jpg

Dieser hat mit dem Multimeter ein 3V ausgangssignal bei Bewegung für 2 
Sekunden.
Nun dachte ich, ich kann einfach das OUT an den Pin 2 (PA1) anschliessen 
kann und damit den Mikrocontroller aufwecken kann.
Leider nicht. Mit dem Multimeter iegen jetzt an OUT nur noch 0V an bei 
Bewegung. Löse ich die Verbindung zwischen Sensor OUT und uC Pin 2 
(PA1), dann messe ich an OUT des Sensors wieder 3V bei Bewegung.

Liegt dies am Pullup des PIN 2 ???
Ich dachte ich könnte mir si vielleicht sogar noch den Taster sparen, 
aber ist doch nicht so einfach. Oder doch und ich mache es falsch?

#include <tinyNeoPixel.h>
#include <avr/sleep.h>
// Which pin on the Arduino is connected to the NeoPixels?
#define PIN            3
// How many NeoPixels are attached to the Arduino?
#define NUMPIXELS      3
tinyNeoPixel strip = tinyNeoPixel(NUMPIXELS, PIN, NEO_GRBW + NEO_KHZ800);
ISR(PORTA_PORT_vect) {
  PORTA.INTFLAGS = PORT_INT1_bm;
}
void setup() {
   pinMode(4, INPUT_PULLUP);
   PORTA.PIN1CTRL = PORT_PULLUPEN_bm;
   delay(100);
   strip.begin();
   set_sleep_mode(SLEEP_MODE_PWR_DOWN);
   sleep_enable();
}
void loop() {
   LightLEDColor(100, 0, 0, 0);
   delay(5000);
   LightLEDColor(0,0,0,0);
   PORTA.PIN1CTRL = PORT_ISC_LEVEL_gc | PORT_INVEN_bm;
   digitalWrite(3, HIGH);
   pinMode(3,INPUT);
   sleep_cpu();
   strip.begin();
   PORTA.PIN1CTRL = PORT_PULLUPEN_bm; 
   strip.begin();   
}
void LightLEDColor(int R, int G, int B, int W)
{
   for (int i = 0; i < NUMPIXELS; i++) {
    strip.setPixelColor(i, strip.Color(R, G, B, W));
    delay(1);
  }
  strip.show();
}

[Georg M. (g_m)]

DerNeue schrieb:
> Nun dachte ich, ich kann einfach das OUT an den Pin 2 (PA1) anschliessen
> kann und damit den Mikrocontroller aufwecken kann.
> Leider nicht.

Doch.


DerNeue schrieb:
> Mit dem Multimeter iegen jetzt an OUT nur noch 0V an bei
> Bewegung. Löse ich die Verbindung zwischen Sensor OUT und uC Pin 2
> (PA1), dann messe ich an OUT des Sensors wieder 3V bei Bewegung.
>
> Liegt dies am Pullup des PIN 2 ???

Mit dem AM312 brauchst du keinen Pullup.

Trotzdem ist etwas falsch. Der Pullup liefert eine positive Spannung und 
der AM312 auch. Woher dann 0V?

[Nummer E. (ritaripp)]

Versuch mal mit AM312 statt Taster:

23  PORTA.PIN1CTRL = PORT_ISC_BOTHEDGES_gc;


und besser

ISR(PORTA_PORT_vect) {
  PORTA.PIN1CTRL = 0; //verhindert mehrfach Interupt
  PORTA.INTFLAGS = PORT_INT1_bm;

}

[Peter D. (peda)]

DerNeue schrieb:
> Normal sollte ja beim drücken der Taste ein High anliegen und damit der
> Mikrocontroller aufwachen. Doch leider macht er das nicht.

Du brauchst eine Flanke zum aufwachen. Nach Loslassen der Taste bleibt 
die Pinkapazität aber auf 5V geladen und denkt gar nicht daran auf 0V zu 
wechseln.

Der AM312 wird bei 5V vermutlich die Grätsche machen.

[DerNeue (Gast)]

Hallo zusammen,

also Danke schonmal für eure Antworten.

Ich habe jetzt mal ein ganz einfachen Code geschrieben. Die LEDs 
leuchten bei einem HIGH des AM312 auf und gehen aus, wenn dieser auf LOW 
ist.

Also der elektrische Aufbau scheint erstmal zu klappen.

Wenn ich in Zeile 13 von INPUT auf INPUT_PULLUP Wechsel, dann klappt es 
nicht mehr. Dann gehen einmal die LEDs an und nicht mehr aus.

Nun ist die Frage. Wie kann ich das in den Sleep Code implementieren?

#include <tinyNeoPixel.h>

// Which pin on the Arduino is connected to the NeoPixels?
#define PIN            3

// How many NeoPixels are attached to the Arduino?
#define NUMPIXELS      3

int StatusMotionOld = 0;
tinyNeoPixel strip = tinyNeoPixel(NUMPIXELS, PIN, NEO_GRBW + NEO_KHZ800);

void setup() {
  pinMode(2, INPUT);
  strip.begin(); // This initializes the NeoPixel library.
}

void loop() {
   int StatusMotion = digitalRead(2);
   if (StatusMotion == StatusMotionOld)
   {}
   else{
   if (StatusMotion == HIGH) {
      strip.begin();
      LightLEDColor(100, 0, 0, 0);
      }
    else
    {
      pinMode(3, INPUT);
      digitalWrite(3, HIGH);
      delay(1000);
      }
    StatusMotionOld = StatusMotion;
   }
}

void LightLEDColor(int R, int G, int B, int W)
{
  for (int i = 0; i < NUMPIXELS; i++) {
    // pixels.Color takes RGBW values, from 0,0,0,0 up to 255,255,255,255
    strip.setPixelColor(i, strip.Color(R, G, B, W)); // Moderately bright green color.
    delay(1);
  }
  strip.show();
}

[Veit D. (devil-elec)]

Hallo,

ernst gemeinter Tipp. Gehe bitte nochmal die Bsp. der IDE durch. Deine 
ständige Konfiguration vom Taster macht keinen Sinn. Eingänge und 
Ausgänge werden in der Regel zu 99% einmal konfiguriert. Danach werden 
nur noch Pegel eingelesen und bei Ausgängen Pegel umgeschalten.

[Georg M. (g_m)]

DerNeue schrieb:
> Nun ist die Frage. Wie kann ich das in den Sleep Code implementieren?

Der hybride Code ist etwas verwirrend, aber AVR ohne Arduino sieht 
ungefähr so aus:

/*------------------------------------------------
  ATtiny412 simple PIR LED control

         VDD 1|‾‾‾‾‾‾‾|8 GND 
         PA6 2|       |7 PA3
         PA7 3|       |6 UPDI 
 PIR --- PA1 4|_______|5 PA2 --- LED

 (PIR Sensor Output Voltage = VDD)
--------------------------------------------------*/

#include <avr/io.h>
#define F_CPU 3333333UL                      // default
#include <util/delay.h>
#include <avr/interrupt.h>
#include <avr/sleep.h>

ISR(PORTA_PORT_vect) 
{
  PORTA.INTFLAGS = PORT_INT1_bm;             // clear the interrupt flag
}

int main(void)
{
  PORTA.PIN1CTRL = PORT_INVEN_bm;             // invert PA1 input
  PORTA.DIRSET = PIN2_bm;                     // set PA2 as output
  SLPCTRL.CTRLA = SLPCTRL_SMODE_PDOWN_gc;     // select Power-Down sleep mode
  sei();                                      // enable global interrupts

  while (1)
  {
    PORTA.OUTSET = PIN2_bm;                   // PA2 ON
    _delay_ms(5000);                          // 5s ON
    PORTA.OUTCLR = PIN2_bm;                   // PA2 OFF

    PORTA.PIN1CTRL &= ~PORT_ISC_gm;           // clear ISC field
    PORTA.PIN1CTRL |= PORT_ISC_LEVEL_gc;      // level interrupt on PA1
    sleep_mode();                             // sleep
                                              // waked if PA1=HIGH
    PORTA.PIN1CTRL &= ~PORT_ISC_gm;           // clear ISC field
    PORTA.PIN1CTRL |= PORT_ISC_INTDISABLE_gc; // disable interrupt on PA1
  }
}