ELM-CHAN, ASM-Wurzel, Fragen zur Nutzung

[Wurzelchen (Gast)]

Hallo zusammen,

ELM-CHAN (http://elm-chan.org/docs/avrlib/sqrt32.S) hat eine AVR-ASM 
Routine zur Wurzel-Berechnung auf seiner Site.
Diese ist vorgesehen zum Einbau in AVR-GCC Projekte.

Ich möche die Routine jedoch in einem reinen ASM-Projekt nutzen und bin 
leider
nicht der Gcc-Notation/Var-Übergabe vertraut.

Könnt Ihr mir hierbei helfen, das wäre nett:

1) In welche Register lege ich denn nun den Eingangswert (uint32_t n)?
2) Und wo liegt am Ende das Ergebnis?
3) Was bedeuten die "seltsamen" Sprungmarken 2f/3f/1b, der Assembler 
würde darüber ja stolpern.

;----------------------------------:
; 32bit integer squareroot
;----------------------------------;
;   uint16_t isqrt32 (uint32_t n);
;
; Return Value:
;   Squareroot of n.
;
; Size  = 53 words
; Clock = 532..548 cycles
; Stack = 0 byte

.global isqrt32
.func isqrt32

isqrt32:
        clr     r0
        clr     r18
        clr     r19
        clr     r20
        ldi     r21, 1
        clr     r27
        clr     r30
        clr     r31
        ldi     r26, 16
1:      lsl     r22
        rol     r23
        rol     r24
        rol     r25
        rol     r0
        rol     r18
        rol     r19
        rol     r20
        lsl     r22
        rol     r23
        rol     r24
        rol     r25
        rol     r0
        rol     r18
        rol     r19
        rol     r20
        brpl    2f          ???????
        add     r0, r21
        adc     r18, r27
        adc     r19, r30
        adc     r20, r31
        rjmp    3f          ???????
2:      sub     r0, r21
        sbc     r18, r27
        sbc     r19, r30
        sbc     r20, r31
3:      lsl     r21
        rol     r27
        rol     r30
        andi    r21, 0b11111000
        ori     r21, 0b00000101
        sbrc    r20, 7
        subi    r21, 2
        dec     r26
        brne    1b         ???????
        lsr     r30
        ror     r27
        ror     r21
        lsr     r30
        ror     r27
        ror     r21
        mov     r24, r21
        mov     r25, r27
        ret
.endfunc

[Alberto (Gast)]

avr-gcc Registerverwendung ist hier erklärt: 
https://gcc.gnu.org/wiki/avr-gcc#Register_Layout

Wenn du die Funktion so anpasst, dass die calling convention eingehalten 
wird und du keine call-saved Register veränderst, dann kannst du die 
Funktion einfach aus C heraus aufrufen.

[Yalu X. (yalu) (Moderator)]

Hier ist (fast) der gleiche Code mit universellen Registernamen. Da
steht auch die Funktion der einzelnen Register mit dabei:

  http://elm-chan.org/docs/avrlib/sqrt32.txt

[Mario M. (thelonging)]

Wurzelchen schrieb:
> Was bedeuten die "seltsamen" Sprungmarken 2f/3f/1b

Das sind lokale Labels und f/b ist die Richtung (forward/backward).
https://ftp.gnu.org/old-gnu/Manuals/gas-2.9.1/html_chapter/as_5.html

[S. Landolt (Gast)]

an Wurzelchen:
Falls Interesse besteht: ich hatte mal aus dem Internet (weiß nicht mehr 
woher genau) eine Routine nach Ruud van Gessel kopiert und für mich 
angepasst; benötigt ca. 300 Takte. Könnte ich ausgraben und hier 
vorstellen.

[Wurzelchen (Gast)]

S. Landolt schrieb:
> Könnte ich ausgraben und hier vorstellen.

Natürlich gerne!
Auf jeden Fall schonmal vielen Dank für alle Antworten,
das hilft mir weiter!

[S. Landolt (Gast)]

Sollte selbsterklärend sein (die Anwendung, nicht der Inhalt), sonst 
eben nachfragen.

[c-hater (Gast)]

S. Landolt schrieb:

> Falls Interesse besteht: ich hatte mal aus dem Internet (weiß nicht mehr
> woher genau) eine Routine nach Ruud van Gessel kopiert

Ja, das Internet ist doch ein wenig vergesslich. Ich habe mich auch 
schonmal bei Ruuds Code als Ausgangspunkt einer eigenen Entwicklung 
bedient. Aber die Quelle dafür, die ich damals verwendet hatte, 
existiert heute nicht mehr.

Möglicherweise ist sie noch über irgendwelche Internet-Archive 
verfügbar, deswegen poste ich trotz der definitiven Nichtverfügbarkeit 
noch mal den Link, den ich damals verwendet hatte:

http://members.chello.nl/j.beentjes3/Ruud/sqrt32avr.htm

Übrigens ist genau diese Routine (bzw. deren Umsetzung in der runtime 
des avr-gcc) eine SEHR schönes Beispiel dafür, wie suboptimal Compiler 
sein können (bzw. sein müssen)...

[[e-mail] (Gast)]

c-hater schrieb:
> http://members.chello.nl/j.beentjes3/Ruud/sqrt32avr.htm

https://web.archive.org/web/20170714160927/http://members.chello.nl/j.beentjes3/Ruud/sqrt32avr.htm