Drehspulmesswerk anschliessen

[Thomas A. (tom2jump)]

Hallo
Es gab hier schon verschiedene Beiträge zu Uhren die mit 
Drehspulmesswerken (3 Stück) betrieben werden.(aber die Links in den 
Beiträgen sind tot)

Nun war ich am Nachbau dieser Uhr:
https://michaelteeuw.nl/post/what-time-is-it-fathers-day

Soweit funktioniert auch alles sehr gut.
Nun ist es aber so das bei dem Drehspulmesswerken Spannungen von 335mV 
bis 5V vom Ausgang des Arduino anliegen.
In dem Moment wo die 5V anliegen und in der nächsten Sekunde wieder die 
335mV anliegen, schlägt der Zeiger des Instrumentes nach links.
Nun ist meine Vorstellung das der Zeiger "sanfter" zurück geht.

Wie kann ich das machen?
Ich dachte an einen Elko parallel zum Instrument.

Ich hoff ich habe es verständlich erklärt.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Thomas A. schrieb:
> Uhren die mit Drehspulmesswerken (3 Stück) betrieben werden.
Da könnte man glatt herauslesen, dass die Versorgung der Uhr aus den 
Messwerken kommt...  ;-)

> Nun ist meine Vorstellung das der Zeiger "sanfter" zurück geht.
> Wie kann ich das machen?
> Ich dachte an einen Elko parallel zum Instrument.
Ja, mach noch einen Widerstand in Reihe. Das nennt sich dann Tiefpass. 
Was hast du denn für Messwerke (wieviele mA bzw. µA)? Und wie hast du 
sie angeschlossen? Evtl. ist ja der Widerstand schon drin.

[H. H. (Gast)]

Lothar M. schrieb:
> Ja, mach noch einen Widerstand in Reihe.

Der ist ja im Messwerkgehäuse schon drin.

Also auch den Kondensator ins Messwerkgehäuse bauen, oder beide nach 
außen.

[Mario M. (thelonging)]

Warum nicht per Software? Statt PWM von 255 direkt auf 0 zu setzen, kann 
man das in mehreren Stufen mit entsprechendem zeitlichen Abstand machen.

[Andrew T. (marsufant)]

Lothar M. schrieb:
> Was hast du denn für Messwerke (wieviele mA bzw. µA)?

Wenn der TE es genau wie der Holländer im weblink gemacht hat: ca. 0,9mA 
.

[Thomas A. (tom2jump)]

Mario M. schrieb:
> Warum nicht per Software? Statt PWM von 255 direkt auf 0 zu setzen, kann
> man das in mehreren Stufen mit entsprechendem zeitlichen Abstand machen.

Nun mit dem programmieren vom Arduino kenne ich mich nicht so aus.
Der Sketch sieht so aus:

/**
 * An Arduino Volt Meter Analog Clock based on a TinyRTC real time clock.
 *
 * For more info about this project, check out my blog for the full story
 * images, and the endresult of the project:
 * http://michaelteeuw.nl/post/174972004187/what-time-is-it- fathers-day
 *
 * LICENSE: Permission is hereby granted, free of charge, to any person
 * obtaining a copy of this software and associated documentation files
 * (the "Software"). For more info see LICENSE file.
 *
 * @category   CategoryName
 * @package    PackageName
 * @author     Michael Teeuw
 * @copyright  2018
 * @license    https://opensource.org/licenses/MIT
 * @link       http://michaelteeuw.nl
 */

#include <Arduino.h>
#include <Wire.h>

#include "RTClib.h" // https://github.com/adafruit/RTClib

// Define the Pins we are using.
#define PIN_BUTTON_HOUR 7
#define PIN_BUTTON_MIN 8
#define PIN_METER_HOUR 3
#define PIN_METER_MIN 5
#define PIN_METER_SEC 6

// Define the minimum and maximum PWM values for all the meters.
// These values can be used to calibrate the meters.
#define MINIMUM_PWM_VALUE_HOUR 15
#define MAXIMUM_PWM_VALUE_HOUR 240
#define MINIMUM_PWM_VALUE_MIN 15
#define MAXIMUM_PWM_VALUE_MIN 254
#define MINIMUM_PWM_VALUE_SEC 15
#define MAXIMUM_PWM_VALUE_SEC 240

// Create the real time clock instance.
RTC_DS1307 rtc;

/**
 * Slowly animate one meter to the maximum value and back.
 * This animation is used in the start sequence. Not only does it look
 * cool. It's also a way to test the meters.
 *
 * @param uint8_t pin  The pin of the meter.
 * @param uint8_t min  The meter's minimum PWM value.
 * @param uint8_t max  The meter's maximum PWM value.
 */
void animateMeter(uint8_t pin, uint8_t min, uint8_t max) {
  uint8_t v;
  for (v = min; v <= max; v++) {
    analogWrite(pin, v);
    delay(2);
  }
  delay(100);
  for (v = max; v >= min; v--) {
    analogWrite(pin, v);
    delay(2);
  }
  delay(100);
}

/**
 * Run the startup sequence by animating all three meters sequentially.
 */
void startSequence() {
  animateMeter(PIN_METER_HOUR, MINIMUM_PWM_VALUE_HOUR, MAXIMUM_PWM_VALUE_HOUR);
  animateMeter(PIN_METER_MIN, MINIMUM_PWM_VALUE_MIN, MAXIMUM_PWM_VALUE_MIN);
  animateMeter(PIN_METER_SEC, MINIMUM_PWM_VALUE_SEC, MAXIMUM_PWM_VALUE_SEC);
}

/**
 * The method to update the time displayed on the the meter.
 */
void displayTime() {
  // Retrieve the time from the real time clock.
  DateTime now = rtc.now();

  // Since the real time clock returns a 24 hour format,
  // we need to convert the hour value to 12 hour format.
  // For minutes and seconds we can just directly use the
  // properties on the 'now' object. No need to store those
  // in a temporary variable.
  int8_t h = (now.hour() == 0 || now.hour() == 12) ? 12 : now.hour() % 12;

  // Convert the time values to PWM values by using map ...
  // and set that value as the PWM value using analogWrite.
  analogWrite(PIN_METER_HOUR, map(h, 1, 12, MINIMUM_PWM_VALUE_HOUR, MAXIMUM_PWM_VALUE_HOUR));
  analogWrite(PIN_METER_MIN, map(now.minute(), 0, 60, MINIMUM_PWM_VALUE_MIN, MAXIMUM_PWM_VALUE_MIN));
  analogWrite(PIN_METER_SEC, map(now.second(), 0, 60, MINIMUM_PWM_VALUE_SEC, MAXIMUM_PWM_VALUE_SEC));

  // For debuging purposes, write the time to the
  // Serial port as well.
  Serial.print(h);
  Serial.print(":");
  Serial.print(now.minute());
  Serial.print(":");
  Serial.println(now.second());
}

/**
 * The setup method used by the Arduino.
 */
void setup () {
  // Initiate the serial port for debugging purposes.
  Serial.begin(9600);

  // Configure all the pin modes for all connected pins.
  pinMode(PIN_BUTTON_HOUR, INPUT_PULLUP);
  pinMode(PIN_BUTTON_MIN, INPUT_PULLUP);
  pinMode(PIN_METER_HOUR, OUTPUT);
  pinMode(PIN_METER_MIN, OUTPUT);
  pinMode(PIN_METER_SEC, OUTPUT);

  // Start the real time clock.
  rtc.begin();

  // If the real time clock is not running,
  // for example after the battery was replaced,
  // start it by setting the time.
  if (!rtc.isrunning()) {
    rtc.adjust(DateTime(2018, 6, 17, 0, 0, 0));
  }

  // Initiate the power-on self test by running the start sequence.
  startSequence();
}

/**
 * The main runloop used by the Arduino.
 */
void loop () {
    // Update the meters by calling the `displayTime()` method.
    displayTime();

    // Check if we pressed the button to adjust the hour ...
    // Repeat the following loop for as long as we hold this button.
    while (!digitalRead(PIN_BUTTON_HOUR)) {
      // Grab the current time.
      DateTime now = rtc.now();

      // Set the RTC time by using the current time and increaing the hour by one.
      // By using the % 24, it will automaticly overflow to 0 when it reaches 24.
      // The seconds are simply reset.
      rtc.adjust(DateTime(now.year(), now.month(), now.day(), (now.hour() + 1) % 24, now.minute(), 0));

      // Update the display to reflect the changes.
      displayTime();

      // Wait half a second before we check again to see
      // if the button is still pressed.
      delay(500);
    }

    // Check if we pressed the button to adjust the minutes ...
    // Repeat the following loop for as long as we hold this button.
    while (!digitalRead(PIN_BUTTON_MIN)) {
      // Grab the current time.
      DateTime now = rtc.now();

      // Set the RTC time by using the current time and increaing the minutes by one.
      // By using the % 60, it will automaticly overflow to 0 when it reaches 60.
      // The seconds are simply reset.
      rtc.adjust(DateTime(now.year(), now.month(), now.day(), now.hour(), (now.minute() + 1) % 60, 0));

      // Update the display to reflect the changes.
      displayTime();

      // Wait a quarter of a second before we check again to see
      // if the button is still pressed.
      delay(250);
    }

    // Wait for 1 second before we start all over again.
    delay(1000);
}

Mod: bitte c-Tags das nächste Mal selber einfügen. Siehe die 
BEdienungsanleitung über jeder Texteingabebox unter "Wichtige Regeln - 
erst lesen, dann posten!"

[Thomas A. (tom2jump)]

Andrew T. schrieb:
> Lothar M. schrieb:
>> Was hast du denn für Messwerke (wieviele mA bzw. µA)?
>
> Wenn der TE es genau wie der Holländer im weblink gemacht hat: ca. 0,9mA
> .

Die Messwerke sind für 300V. Da ist intern ein Widerstand zwischen "+" 
und Messwerk in Reihe von 115k Ohm verbaut. Zwischen "-" und Messwerk 
eine Diode.
Parallel zum Messwerk ein Elko.
Getauscht wurde nur der Widerstand auf 4,7k um die 300V Messwerke für 5V 
zu nutzen.

[Andrew T. (marsufant)]

Thomas A. schrieb:
> Andrew T. schrieb:
>> Lothar M. schrieb:
>>> Was hast du denn für Messwerke (wieviele mA bzw. µA)?
>>
>> Wenn der TE es genau wie der Holländer im weblink gemacht hat: ca. 0,9mA
>> .
>
> Die Messwerke sind für 300V. Da ist intern ein Wider....
> Getauscht wurde nur der Widerstand auf 4,7k um die 300V Messwerke für 5V
> zu nutzen.


Der Holländer schreibt 5,6,k um auf 5V Fullscale  zu kommen.
Daher schrieb ich 0,9 mA

[Thomas A. (tom2jump)]

Andrew T. schrieb:
> Der Holländer schreibt 5,6,k um auf 5V Fullscale  zu kommen.
> Daher schrieb ich 0,9 mA

Das sind Voltmeter. Hat ja nichts mit Ampere zu tun.
Der Holländer hat auch probiert welcher Widerstand passt um die Skala 
bei 5V zu nutzen. Bei mir sind es 4,2k bzw. 4,7k je nach Messwerk. 
Später werde ich die Festwiderstände durch 10Gang Spindel-Widerstände 
ersetzen um bei 5V 100% die Skala zu nutzen. Da haben die Messwerke halt 
eine Toleranz.(China halt)

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Thomas A. schrieb:
> Das sind Voltmeter. Hat ja nichts mit Ampere zu tun
Ausnahmslos jedes magnetische Drehspulmessgerät ist ein Strommesser. 
Die Spannung wird durch einen Vorwiderstand in einen passenden Strom 
umgewandelt, der zum gewünschten Ausschlag führt.

> Bei mir sind es 4,2k bzw. 4,7k je nach Messwerk.
Dann mach einfach hinter diesen Widerstand deinen Elko im Bereich um 
100µF.

Thomas A. schrieb:
> Die Messwerke sind für 300V.
Ach so, AC. Und die Diode hat nur 1 Halbwelle durchgelassen. Dann passen 
die 0,9mA wieder zu den 115k.

> Parallel zum Messwerk ein Elko.
Welchen Wert hat der?

Mein Tipp: überbrücke die Diode, dann sind auch die blöden 350mV Offset 
weg.

[Thomas A. (tom2jump)]

Lothar M. schrieb:
>> Bei mir sind es 4,2k bzw. 4,7k je nach Messwerk.
> Dann mach einfach hinter diesen Widerstand deinen Elko im Bereich um
> 100µF.
>
Dann bewegt sich der Zeiger nicht mehr.

> Thomas A. schrieb:
>> Die Messwerke sind für 300V.
> Ach so, AC. Und die Diode hat nur 1 Halbwelle durchgelassen. Dann passen
> die 0,9mA wieder zu den 115k.
>
>> Parallel zum Messwerk ein Elko.
> Welchen Wert hat der?
>
47µF
> Mein Tipp: überbrücke die Diode, dann sind auch die blöden 350mV Offset
> weg.
Ohne Diode sind die 335mV immer noch zu messen. Aber das ist kein 
Problem.

[Mario M. (thelonging)]

Thomas A. schrieb:
> Nun mit dem programmieren vom Arduino kenne ich mich nicht so aus.
> Der Sketch sieht so aus

Ok, ist der übliche Arduino-delay-Müll, da kommt der Einbau einer 
Decay-Funktion einer Neuprogrammierung gleich. Also besser doch die 
Kondensator-Variante.

Thomas A. schrieb:
> Ohne Diode sind die 335mV immer noch zu messen. Aber das ist kein
> Problem.

Der Offset ist notwendig, um bei den verwendeten DrehEISENmesswerken aus 
dem nichtlinearen Bereich der Skala zu kommen.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Mario M. schrieb:
> Ok, ist der übliche Arduino-delay-Müll, da kommt der Einbau einer
> Decay-Funktion einer Neuprogrammierung gleich.
Genau das habe ich mir auch gedacht. Wenn ich ein delay(1000) sehe, weiß 
ich sicher, dass so ein Programm ohne Nachdenken kurz mal lieblos 
hingekritzelt und garantiert nicht einfach erweiterbar ist.

Thomas A. schrieb:
> Dann bewegt sich der Zeiger nicht mehr.
Dann hast du irgendwas falsch gemacht. Denn wenn der Zeiger mit den 
bestehenden 47µF an den Anschlag knallt, dann ist es *äusserst 
unwahrscheinlich*, dass er sich mit 100µF gar nicht mehr bewegt.

Thomas A. schrieb:
> 47µF
>> Mein Tipp: überbrücke die Diode, dann sind auch die blöden 350mV Offset
>> weg.
> Ohne Diode sind die 335mV immer noch zu messen.
Na klar, du gibst die ja auch aus. Aber: der Zeiger schlägt dann schon 
aus, wo er vorher noch links am Anschlag geklebt hat.

Ich würde an dieser Stelle dringend vorschlagen, dass du mal versuchst, 
deine Schaltung wie in der Elektronik üblich in einen Schaltplan zu 
malen. Denn Schaltpläne sind die Sprache der Elektronik.

[H. H. (Gast)]

Thomas A. schrieb:
> Parallel zum Messwerk ein Elko.
> Getauscht wurde nur der Widerstand auf 4,7k um die 300V Messwerke für 5V
> zu nutzen.

Wenn man den Vorwiderstand in zwei Hälften teilt, und den Elko 
dazwischen anschließt, dann braucht man weniger Kapazität.

[Mario M. (thelonging)]

Meine Überschlagsrechnung ergibt, dass das Messwerk einen 
Innenwiderstand von ca. 400 Ohm haben dürfte. Da die vollständige 
Umladung eines Kondensators ca. 5 Tau dauert, ergibt sich bei einer 
Kapazität von 100 uF eine Zeit von rund 0,2 Sekunden, was fast noch 
etwas zu wenig wäre.

[Dietrich L. (dietrichl)]

Lothar M. schrieb:
> Thomas A. schrieb:
>> Dann bewegt sich der Zeiger nicht mehr.
> Dann hast du irgendwas falsch gemacht. Denn wenn der Zeiger mit den
> bestehenden 47µF an den Anschlag knallt, dann ist es *äusserst
> unwahrscheinlich*, dass er sich mit 100µF gar nicht mehr bewegt.

Vielleicht hat er den Kondensator in Reihe geschaltet?

[Thomas A. (tom2jump)]

so. Habe wieder Zeit mich mit dem Problem zu beschäftigen. Habe leider 
nicht immer die Zeit dafür.
In Bild 1 ist die originale Beschaltung des Messwerkes. Diese hatte ich 
nur soweit geändert indem ich den Widerstand (von 115k zu 4,7k) an die 
Skala angepasst habe (Bild 2). Dann habe ich versucht den 25µF Elko 
durch 100µF bzw. 1000µF zu ersetzen.
Bei 1000µF bewegt sich meiner Meinung nach der Zeiger nicht linear.

Bei der Schaltung Bild 3 habe ich mit den gleichen Werten von Elko 
experimentiert.

[Rainer W. (rawi)]

Thomas A. schrieb:
> Der Sketch sieht so aus:
> <viele Seiten Quellcode>
> ...

Wichtige Regeln - erst lesen, dann posten!
Längeren Sourcecode nicht im Text einfügen, sondern als DATEIANHANG

Warum programmierst du kein Tiefpassfilter vor die Ausgabe des 
Analogwertes?

[Enrico E. (pussy_brauser)]

Ich habe deine Schaltung mal so abgeändert, wie Herr Hinz das richtiger 
Weise vorgeschlagen hat, dann sind endlich alle Probleme wie 
weggeblasen:

H. H. schrieb:
> Wenn man den Vorwiderstand in zwei Hälften teilt, und den Elko
> dazwischen anschließt, dann braucht man weniger Kapazität.

[Thomas A. (tom2jump)]

Rainer W. schrieb:
> Warum programmierst du kein Tiefpassfilter vor die Ausgabe des
> Analogwertes?

Tiefpassfilter programmieren?
Kenne ich nur Hardware seitig.

[Thomas A. (tom2jump)]

Enrico E. schrieb:
> Ich habe deine Schaltung mal so abgeändert, wie Herr Hinz das richtiger
> Weise vorgeschlagen hat, dann sind endlich alle Probleme wie
> weggeblasen:
>
> H. H. schrieb:
>> Wenn man den Vorwiderstand in zwei Hälften teilt, und den Elko
>> dazwischen anschließt, dann braucht man weniger Kapazität.

Danke. Versuche ich mal.

[Thomas A. (tom2jump)]

Gerade mal getestet.
Funktioniert richtig schön.
Dann möchte ich mich mal bei allen Beteiligten bedanken.

[Rainer W. (rawi)]

Thomas A. schrieb:
> Tiefpassfilter programmieren?
> Kenne ich nur Hardware seitig.

Wurde doch hier gerade ausführlich diskutiert:
Beitrag "Eigenschaften des Moving Avarage Filters"

Um eine ähnliche Wirkung wie mit dem Kondensator zu erzielen, könnte man 
das TP-Filter z.B. alle 50ms aktualisieren und mit dem Ausgangswert den 
PWM-Ausgang füttern.