Fehler beim Öffnen der Datei

[Realschule D. (realschule_d)]

Hallo zusammen,

für ein Projekt an unserer Schule habe ich einen Arduino Nano mit 
unterschiedlichen Sensoren verbunden und will diese gewonnenen Daten auf 
einer SD-Karte speichern. Die Sensoren habe ich einzeln überprüft und 
diese haben reagiert. Leider komme ich beim Speichern der Ergebnisse 
nicht weiter und hoffe ihr könnt mir helfen. Compiling hat funktioniert, 
Initialisierung der SD-Karte auch erfolgreich, aber dann wird der 
Fehler: "Fehler beim Öffnen der Datei" geworfen. Die SD Karte ist nur 
1GB groß und wurde mit SD Format frisch formatiert.

Hier der Code:

#include <SPI.h>
#include <SD.h>
#include <Adafruit_BMP085.h>

File meineDatei;
Adafruit_BMP085 bmp;

void setup() {
  // SD-Karte initialisieren
  Serial.begin(9600);
  while (!Serial) {
    ; // warten auf serielle Portverbindung.
  }

  if (!bmp.begin()) {
  Serial.println("Could not find a valid BMP085 sensor, check wiring!");
  while (1) {}
  }

  if (!SD.begin(10)) {
    Serial.println("Initialisierung fehlgeschlagen!");
    return;
  }
  Serial.println("Initialisierung erfolgreich.");

  // Öffnen der Datei. Beachten Sie, dass nur ein Programm zur Zeit auf die Datei schreiben kann.
  meineDatei = SD.open("ergebnisse.txt", FILE_WRITE);

  // Schreiben Sie die Ergebnisse der Programme in die Datei
  if (meineDatei) {
    meineDatei.println("Ergebnisse von Programm 1:");
    meineDatei.println(programm1());
    meineDatei.println("Ergebnisse von Programm 2:");
    meineDatei.println(programm2());
    meineDatei.println("Ergebnisse von Programm 3:");
    meineDatei.println(programm3());
    meineDatei.println("Ergebnisse von Programm 4:");
    meineDatei.println(programm4());

    // Schließen der Datei
    meineDatei.close();
  } else {
    // wenn das Öffnen der Datei fehlschlägt:
    Serial.println("Fehler beim Öffnen der Datei");
  }
}

void loop() {
  // Nichts zu tun hier
}

String programm1() {
  int TMP36 = A1;
  int sensorwert;
  int temperatur = 0;
  int t = 500;

  sensorwert = analogRead(TMP36);
  temperatur = map(sensorwert, 0, 410, -50, 150);
  delay(t);
  return String(temperatur) + " Grad Celsius";
}

String programm2() {
  int xA = analogRead(A3);
  int yA = analogRead(A2);
  int zA = analogRead(A6);

  return String(xA) + "," + String(yA) + "," + String(zA);
}

String programm3() {
  const byte soundpin = A0;
  int sample = analogRead(soundpin);
  float volt_calc = sample * (5.0 / 4096.0);

  return String(sample) + "\t" + String(volt_calc);
}

String programm4() {
  
  float temp = bmp.readTemperature(); // °C
    
  float press = bmp.readPressure(); // Pa
    
  float alt = bmp.readAltitude(); // meters

  return String(temp) + "\t" + String(press) + "\t" + String(alt) ;
}

Vielen Dank schon Mal für eure Ideen!

Gruß, Roman

[Harald K. (kirnbichler)]

Realschule D. schrieb:
> "ergebnisse.txt"

Das entspricht nicht der 8.3-Namenskonvention, kann denn der 
FAT-Treiber, den Du da verwendest, mit langen Dateinmen umgehen?

Probier einfach mal "TEST.TXT" aus.

[Wastl (hartundweichware)]

Realschule D. schrieb:
> Vielen Dank schon Mal für eure Ideen!

Dann üben wir noch das Lesen der Hinweise zum Posten
von Code:

Längeren Sourcecode nicht im Text einfügen, sondern als Dateianhang

und

[c ]C-Code [/c ]

[Hmmm (hmmm)]

"The library supports FAT16 and FAT32 file systems on standard SD cards 
and SDHC cards. It uses short 8.3 names for files."

https://www.arduino.cc/reference/en/libraries/sd/

[Harald K. (kirnbichler)]

Hmm. Hab' ich wohl nicht die falsche Frage gestellt.

[Realschule D. (realschule_d)]

Hallo,

das war's. Ich hab es auf result.txt geändert und es funktioniert!

Danke!